Masquer barre Excel

Bonjour

J'arrive à masquer certaines barres dans excel ,mais celle dont je joins la photo je n'y arrive pas

Merci pour votre aide

Bonjour,

voici ce que j'utilise :

' **********************************************************
' * procédure de lancement de jeu avec mise en plein écran *
' **********************************************************
Sub Jouons()
    Dim I
    ' on arrête la mise à jour de l'écran
    Application.ScreenUpdating = False
    ' on active la feuille de jeu
    Sheets("Jeu").Activate
    ' avec la fenêtre active (normalement celle de jeu sous Excel)
    With ActiveWindow
        ' les titres (A et 1)
        .DisplayHeadings = False
        ' scroll barre horizontale
        .DisplayHorizontalScrollBar = False
        ' scroll barre verticale
        .DisplayVerticalScrollBar = False
        ' les onglets
        .DisplayWorkbookTabs = False
    End With
    ' avec l'application Excel
    With Application
        ' le ruban
        .ExecuteExcel4Macro "SHOW.TOOLBAR(""Ribbon"",False)"
        ' la barre de formule
        .DisplayFormulaBar = False
        ' barre de status
        .DisplayStatusBar = False
        ' on met à jour l'écran
        .ScreenUpdating = True
    End With
    ' on appel le code de jeu
    Call MainCode
End Sub

' *********************************
' * retour à la normal sous Excel *
' *********************************
Sub RetourNormal()
    Dim I
    ' avec l'application
    With Application
        ' on arrête la mise à jour de l'écran
        .ScreenUpdating = False
        ' le ruban
        .ExecuteExcel4Macro "SHOW.TOOLBAR(""Ribbon"",True)"
        ' la barre de formule
        .DisplayFormulaBar = True
        ' barre de status
        .DisplayStatusBar = True
    End With
    ' avec la fenêtre
    With ActiveWindow
        ' les titres (A et 1)
        .DisplayHeadings = True
        ' scroll barre horizontale
        .DisplayHorizontalScrollBar = True
        ' scroll barre verticale
        .DisplayVerticalScrollBar = True
        ' les onglets
        .DisplayWorkbookTabs = True
    End With
    ' on affiche la feuille accueil
    Sheets("Accueil").Activate
    ' on remet en place la mise à jour de l'écran
    Application.ScreenUpdating = True
    ' on stoppe le jeu
    End
End Sub

@ bientôt

LouReeD