Insérer une case à cocher dans une cellule via une macro

Bonjour,

je souhaite insérer en A24 une case à cocher via une macro

Je sais le faire via développeur manuellement mais je ne connais pas la formule vba

une idée pour moi ?

merci de votre retour

très belle journée

Bonjour,

Un exemple, avec comme cellule liée, la cellule B24 :

Sub Insert_Chk()
Dim Sh As Worksheet
Dim Chk As OLEObject
Dim Cel As Range
Set Sh = ActiveSheet: Set Cel = Sh.Range("A24")
Set Chk = Sh.OLEObjects.Add("Forms.CheckBox.1")
With Chk
    .Left = Cel.Left
    .Top = Cel.Top
    .Width = Cel.Width
    .Height = Cel.Height
    .LinkedCell = Cel.Offset(, 1).Address
    .Object.Caption = "Essai insertion"
    .Object.Value = False
End With
End Sub

Bon courage

merci c'est parfait !

très bonne journée

Autre petite question à ce sujet @cousinhub : quand je click sur cette case j'aimerai que cela sélectionne la ligne concernée en la grisant par exemple

Est ce possible ?

merci de ton retour

Re-,

Ce code, inséré dans l'évènement de la feuille où se situe le Chk, te coloriera de Axx à Exx en gris si Vrai (ou l'inverse) :

Private Sub CheckBox1_Click()
Range("A" & Me.CheckBox1.TopLeftCell.Row).Resize(1, 5).Interior.ColorIndex = IIf(Me.CheckBox1, 48, 0)
End Sub

L'instruction .TopLeftCell.Row te donne la ligne du Chk