Index en fonction d'un critère power query

Bonjour,

Je voudrais mettre un index qui commence à 1 et qui augmente de 1à chaque chagnement de "STATUT" et "ANNEE" ou à chaque fois que le CODE TVA est vide.

J'ai mis un exemple ci-dessous

Pour ma part je n'y arrive pas, merci d'avance

Cordialement,

Bonjour à tous !

Une proposition en J2 :

=SI(A2&B2<>A1&B1;SOMME(J1)+1;J1)

Remarque : Le résultat attendu présenté n'indique aucune incrémentation si le CODE TVA est vide......

Bonjour JFL,

Merci cela est parfait mais j'ai oublier de préciser je voudrais le faire par power query si c'est possible

Merci d'avance

Bonjour,

Si VBA est permis, une solution avec les événements SelectionChange et Change dans un tableau structuré.

Bonjour,

Merci cela fonctionne aussi mais je voudrais par power query car mon tableau est sur power query.
Maintenant merci pour c'est différentes solutions si cela se reproduit je serais que l'on peux le faire autrement

Cordialement,

Bonjour,

À chaque changement de Statut et Année. Je n'ai pas tenu compte des nulls, cela ne me semblait pas nécessaire dans l'exemple.

Il suffit de grouper, ajouter l'index, puis dégrouper.

let
  Source = Excel.CurrentWorkbook(){[Name = "Tableau1"]}[Content], 
  Groupes = Table.Group(
    Source, 
    {"STATUT", "ANNEE"}, 
    {
      {
        "AllData", 
        each _, 
        type table [
          STATUT = text, 
          ANNEE = number, 
          LIBELLE = text, 
          CLE = number, 
          COMPTE = number, 
          MONTANT = number, 
          CODE TVA = nullable text, 
          BUDGET = nullable text, 
          AFFECTATION = nullable text
        ]
      }
    }, 
    GroupKind.Local
  ), 
  Index = Table.AddIndexColumn(Groupes, "Index", 1, 1, Int64.Type), 
  Expand = Table.ExpandTableColumn(
    Index, 
    "AllData", 
    {"LIBELLE", "CLE", "COMPTE", "MONTANT", "CODE TVA", "BUDGET", "AFFECTATION"}, 
    {"LIBELLE", "CLE", "COMPTE", "MONTANT", "CODE TVA", "BUDGET", "AFFECTATION"}
  )
in
  Expand

A+

Bonjour,

Merci cela fonctionne parfaitement, merci encore c'est good 😊

Cordialement,

maverick59264 a écrit :

Merci cela est parfait mais j'ai oublier de préciser je voudrais le faire par power query.....

Fâcheuse omission....

Bonjour JFL,

Je sais 😊

Cordialement,