Formule Si imbriquée

Bonjour tout le monde

Merci de m'aider a simplifier cette formule!!!!!

La cellule A6 contient les mois dans une liste déroulante et je veux avoir mon titre qui s'adapte avec les mois.

=SI(TEXTE(A6;"mmmm")="avril";"PROGRAMME REALISE EN MOIS D' "&(MAJUSCULE(TEXTE(A6;"mmmm"))&" / 2020 Etabli par Mr ATOT");SI(TEXTE(A6;"mmmm")="août";"PROGRAMME REALISE EN MOIS D' "&(MAJUSCULE(TEXTE(A6;"mmmm"))&" / 2020 Etabli par Mr ATOTO");SI(TEXTE(A6;"mmmm")="octobre";"PROGRAMME REALISE EN MOIS D' "&(MAJUSCULE(TEXTE(A6;"mmmm"))&" / 2020 Etabli par Mr ATOTO");"PROGRAMME REALISE EN MOIS DE "&(MAJUSCULE(TEXTE(A6;"mmmm"))&" / 2020 Etabli par Mr ATOTO"))))

Bonjour Atoto, le forum,

Un essai:

=SI(OU(A6="avril";A6="août";A6="octobre");"PROGRAMME REALISE EN MOIS D' " & MAJUSCULE(A6);"PROGRAMME REALISE EN MOIS DE " & MAJUSCULE(A6))

Cordialement,

Bonjour

La cellule A6 contient des dates ex 01/04/2020 et je veux extraire seulement le mois ex Avril pour le placer dans mon titre.

Bonjour,

sur la même base :

=SI(OU(MOIS(A6)=4;MOIS(A6)=8;MOIS(A6)=10);"PROGRAMME REALISE EN MOIS D' "&(MAJUSCULE(TEXTE(A6;"mmmm"))&" / 2020 Etabli par Mr ATOT");"PROGRAMME REALISE EN MOIS DE "&(MAJUSCULE(TEXTE(A6;"mmmm"))&" / 2020 Etabli par Mr ATOT"))

Re,

Bonjour cousinhub,

J'en suis resté là :

=SI(OU(TEXTE(A6;"mmmm")="avril";TEXTE(A6;"mmmm")="août";TEXTE(A6;"mmmm")="octobre");"PROGRAMME REALISE EN MOIS D' " & MAJUSCULE(TEXTE(A6;"mmmm"))&" / 2020 Etabli par Mr ATOTO";"PROGRAMME REALISE EN MOIS DE " & MAJUSCULE(TEXTE(A6;"mmmm"))&" / 2020 Etabli par Mr ATOTO")

Cordialement,

Sinon, pour le fun....

="PROGRAMME REALISE EN MOIS D"&SI(OU(MOIS(A6)=4;MOIS(A6)=8;MOIS(A6)=10);"' ";"E ")&MAJUSCULE(TEXTE(A6;"mmmm"))&" / 2020 Etabli par Mr ATOT"

Re,

Difficile de faire plus court,

Cordialement,

c'est génial merci d'avoir partagé gratuitement ton savoir-faire.

Rechercher des sujets similaires à "formule imbriquee"