Formule pour doublons

Bonjour,

Existe-t-il une formule (à saisir en B4) pour alerter d’un doublon sur une donnée ?
J’aimerai éviter la mise en forme conditionnelle avec doublons car les cellules sont déjà colorées différemment pour d’autres besoins.
En vous remerciant.

Bonjour,

A tester: formule à mettre en C5

=SI(NB.SI.ENS(B5:B20;B5)>1;"Doublon";"-")

Slts

Bonjour à tous !

Une autre proposition ?
En B4 :

=LET(
p;B5:B20;
d;FILTRE(p;EQUIVX(p;p)<>SEQUENCE(LIGNES(p));"");
nd;SI(PRENDRE(d;1)="";0;NBVAL(d));
"Doublon"&SI(nd>1;"s";"") & " : " & SI(nd=0;"Néant";JOINDRE.TEXTE(", ";;d))
)

La formule retourne les doublons détectés.

Bonjour à tous,
Une autre formule.
Cdlt.

=LET(a;B5:B20;TEXTJOIN(", ";;UNIQUE(FILTER(a;COUNTIFS(a;a)>1;"pas de doublon"))))

Un grand merci pour vos retours respectifs 🥹
j’ai utilisé votre formule JBL et je ne pouvais pas espérer mieux car elle identifie parfaitement chaque doublon.

Bonsoir à tous !

Bien...

Je vous remercie de ce retour.

Re,
Pour le fun et en français !
Cdlt.

=LET(a; B5:B20; b; JOINDRE.TEXTE(", "; 1; UNIQUE(FILTRE(a; NB.SI.ENS(a; a) > 1; "aucun"))); "Doublon(s) : " & b)