Fonction "Si" imbriquée avec des "Et"

Bonjour, j'ai un soucis de conception avec ma formule SI.

J'aimerais pouvoir avoir dans la cellule H9 le résultat de ce raisonnement :

Si la date de départ est un samedi et que le nbr de jour est sup à 3 alors :

1. (B2*D2)+((C2*D2)*(G2-3))
2. (B2*D2)

Cette formule avec le si imbriquée avec le ET, j'y arrive et je pense que c'est la formule suivante

=SI(ET(JOURSEM(E2;1)=7;G2>3);(B2*D2)+((C2*D2)*(G2-3));B2*D2)

Mais j'aimerais rajouter une condition en plus de la 1ère, que si la date de départ n'est pas un samedi et que le nbr de jour est sup à 3 alors :

1. (A2*D2)+((C2*D2)*(G2-3))
2. (A2*D2)

Et malheureusement je n'arrive pas à imbriquer cette dernière condition

=SI(ET(JOURSEM(E2;1)<>7;G2>3);(A2*D2)+((C2*D2)*(G2-3));A2*D2)

avec mon 1er si

Est-ce que je pourrais avoir de l'aide

Merci.

Salut,

Je n'ai pas très bien compris ce que tu souhaites comme résultats, mais en ce qui concerne ta formule, celle-ci devrait faire l'affaire :

=SI(ET(JOURSEM(E2;1)=7;G2>3);111;SI(ET(JOURSEM(E2;1)<>7;G2>3);222;333))

Tu remplaces 111 par le résultat que tu souhaites si c'est un samedi et que le nombre de jour est supérieur à 3, tu remplaces 222 par le résultat que tu souhaites si ce n'est pas un samedi et que le nombre de jour est supérieur à 3 et 333 par les autres résultats possibles.

Amicalement.

Merci beaucoup, c'est en bonne voie

Mais il me manque encore une valeur à la formule

=SI(ET(JOURSEM(E2;1)=7;G2>3);(B2*D2)+((C2*D2)*(G2-3));SI(ET(JOURSEM(E2;1)<>7;G2>3);(A2*D2)+((C2*D2)*(G2-3));(A2*D2)))

dans le cas ou c'est un samedi et que G2<3 alors je devrais avoir (B2*D2) et là j'ai (A2*D2)

C'est le seul cas qui ne fonctionne pas

Re,

Tu n'avais pas énoncé clairement cette dernière condition. Je l'ai maintenant rajoutée dans la formule.

A noter que tu as précisé le résultat voulu si c'est un samedi et un nombre de jours plus élevé que 3, si un samedi et un nombre de jours moins élevé que 3, mais tu n'as pas précisé ce qu'il faut faire si c'est un nombre de jours égal à 3. J'ai donc décidé de placer dans la deuxième partie de la formule <=3 (plus petit ou égal à 3).

A noter encore que la partie ci-dessous est inutile, puis que si ce n'est pas un samedi, c'est toujours un autre jour !

ET(JOURSEM(E2;1)<>7

Voici donc la formule épurée

=SI(ET(JOURSEM(E2;1)=7;G2>3);(B2*D2)+((C2*D2)*(G2-3));SI(ET(JOURSEM(E2;1)=7;G2<=3);(B2*D2);SI(G2>3;(A2*D2)+((C2*D2)*(G2-3));(A2*D2))))

Chaleureusement.

C'est parfait encore merci