Fonction barré transféré sur une autre feuille

Bonjour,

Depuis des semaines je parcours le net pour trouver une solution.

Chaque semaine j'ai des réunions de chantier et je tape un compte rendu.

J'ai des lignes que je barre a chaque fois que l'étape est réalisée.

ma question la voici:

je voudrais que la cellule si elle est barré seulement soit copier sur la page suivante

cependant je souhaiterai qu'elle ne figure plus dans mon compte rendu.

C'est comme avoir une page avec les tache à faire et une autre avec les tache terminée en gardant la même mise en page

J'espère que vous m'avez compris.

merci de votre aide

Bonjour,

Pour faciliter la compréhension, peux-tu transmettre un fichier illustratif/fictif/anonymisé dans lequel tu nous mets ce que tu as actuellement et un aperçu de ce que tu souhaite obtenir ?

bonjour

voici un pièce jointe pour exemple

merci pour votre aide

Voici une proposition :

Private Sub Worksheet_SelectionChange(ByVal Target As Range)

Dim Resultat As Variant, LigDest As Integer, Lig As Integer

If Target.Column = 3 And Target.Value = "non" Then
    For Lig = Target.Row To 1 Step -1 'Parcourir les lignes pour retrouver le titre le plus proche
        If Cells(Lig, 1).Value = "titre" Then
            With Feuil2
                Set Resultat = .Columns(2).Find(Cells(Lig, 2).Value, LookIn:=xlValues, LookAt:=xlWhole) 'Cherche la position du titre correspondant en feuille 2
                If Not Resultat Is Nothing Then
                    .Rows(Resultat.Row + 1).Insert Shift:=xlDown 'Insert une ligne vierge sous le titre
                    LigDest = Resultat.Row + 1 'Affecte le n° de cette ligne dans une variable
                Else
                    MsgBox "Section non retrouvée en feuille 2" 'Message d'erreur si pas de correspondance du titre
                    Exit Sub
                End If
            End With
            Exit For
        End If
    Next Lig
    Target.EntireRow.Copy Feuil2.Rows(LigDest) 'Copie la ligne en feuille 2
    Target.EntireRow.Delete 'Supprimer la ligne en feuille 1
End If

End Sub

PREREQUIS :

• Présence du mot "titre" en colonne A des lignes de titre (voir dans le fichier, la police est de la même couleur que le fond pour rester invisible)
• Feuille de report dois être la 2ème feuille du classeur (sinon adapter le code)
• La macro ne se base pas sur le fait que la police d'écriture est barrée, mais sur la présence d'un "non" en colonne C