Erreur dans le calcul du jour de Pâques

Bonsoir,

En répondant à un post, je constate que le calcul du jour de Pâques est erroné il devrait tomber le 09/04/2023 alors que le fichier affiche le 08/04/2023.

Si quelqu'un voit où est l'erreur cela m’intéresse.

Cordialement

Bonjour,

Je pense que l'erreur est due au choix du calendrier dans les options avancées d'excel, il faut prendre le calendrier depuis 1900.

Cdlt

Bonjour,

Effectivement, vous utilisez le calendrier depuis 1904. Une solution est d'utiliser ma fonction gérant les 2 calendriers :

  
Function Paques(année As Integer) As Date

    Dim s_an As Integer, q_an As Integer, c_an As Integer  'nb siècles année,  nb quadriannées de l'année, complément de l'année
    Dim nb_or               ' nombre d'or : rang de l'année dans le cycle lunaire de Méton
    Dim m                   ' métemptose : correction calenrier lunaire pour les années bissextiles
    Dim p                   ' proemptose : année de correction du cycle lunaire de Méton
    Dim Rp0 As Integer      ' reliquat pascal brut = nombre de jours entre le 21 mars (équinoxe) et le 14ème jour de lune
    Dim Rp As Integer       ' reliquat pascal après application éventuelle de la proemptose
    Dim Ep As Integer       ' écart pascal = nombre de jours entre le 14ème jour de lune et samedi le plus proche
    Dim Dp As Integer       ' quantième pascal = nombre de jours entre le 21 mars et le samedi saint

    ' Décomposition année en siècle + nombre de quadriannées + complément
    s_an = année \ 100:  q_an = (année - s_an * 100) \ 4: c_an = année - s_an * 100 - q_an * 4
    ' Nombre d'or
    nb_or = année Mod 19
    'Métemptose et Proemptose
    m = s_an - (s_an \ 4): p = (8 * s_an + 13) \ 25
    'Reliquat pascal brut et corrigé
    Rp0 = (15 + 19 * nb_or + m - p) Mod 30: Rp = Rp0 - ((nb_or + 11 * Rp0) \ 319)
    'Ecart pascal
    Ep = (4 - s_an \ 4 + 2 * s_an + 2 * q_an - c_an - Rp) Mod 7
    'Quantième pascal
    Dp = Rp + Ep
    'Date de Pâques
    If Not ThisWorkbook.Date1904 Then Paques = DateAdd("d", Dp + 1, DateSerial(année, 3, 21)) _
    Else Paques = DateAdd("d", Dp, DateSerial(année - 4, 3, 21))

End Function

Bonjour,

Merci pour vos réponses, le problème vient bien de là. N'étant pas mon fichier, je ne sais pas pour quelle utilité cette option a été cochée.

Mais je note la solution pour l'avenir.

Bonne journée à vous,
Cordialement

Merci pour vos réponses, le problème vient bien de là. N'étant pas mon fichier, je ne sais pas pour quel utilité cette option a été cochée.

A priori cette option est utilisée pour les EXCEL version Mac ou pour , il me semble, gérer des heures négatives.

voila ce que j'ai trouvé et modifié...

bonne soirée