Double clic sur cellule ajout valeur et couleur

Bonjour à tous.

J'espère trouver mon bonheur grâce à vous.

J'ai effectivement trouvé des choses sur ce forum, mais pas la concaténation des 2 éléments que j'aimerai.

Je vous explique rapidement ce que j'aimerai mettre en place.

Au double clic sur n'importe quelle cellule de ma feuille, celle ci passe d'une couleur, avec le chiffre 1 de la même couleur

Si je clique à nouveau il m'affiche une autre couleur et le chiffre 2 de la même couleur et jusqu'à 3

Ci dessous le code qui marche bien pour changer la couleur de ma cellule (sur 3 couleurs max)

Private Sub Worksheet_BeforeDoubleClick(ByVal Target As Range, Cancel As Boolean)

Dim couleurs()

couleurs = Array(RGB(87, 62, 194), RGB(0, 134, 61), RGB(255, 255, 255))

On Error GoTo color

Target.Interior.color = couleurs(Application.WorksheetFunction.Match(Target.Interior.color, couleurs, 0) Mod 3)

Cancel = True

Exit Sub

color:

Target.Interior.color = couleurs(0)

Cancel = True

End Sub

Mais je n'arrive pas à associer un chiffre à la couleur ainsi que la couleur du chiffre associé à la couleur de la cellule

Merci par avance pour votre aide

Bon weekend par avance

Salut Tout nu dans l'escalier!

Ça sent le vécu!

Comme tes couleurs n'ont pas l'air plus spéciales que ça, tu pourrais jouer avec COLORINDEX plutôt que COLOR car ces couleurs sont identifiées par un Integer (de 0 à 56).

A+

Bonjour à tous

Un essai à tester, bien que je ne vois pas trop l'intérêt d'avoir une police de même couleur que le fond....

Private Sub Worksheet_BeforeDoubleClick(ByVal Target As Range, Cancel As Boolean)
    Dim couleurs(), nbre(), couleur
    couleurs = Array(RGB(87, 62, 194), RGB(0, 134, 61), RGB(255, 255, 255))
    nbre = Array(1, 2, 3)
    On Error GoTo color
    couleur = couleurs(Application.WorksheetFunction.Match(Target.Interior.color, couleurs, 0) Mod 3)
    Target.Interior.color = couleur
    Target.Font.color = couleur
    Target = nbre(Application.WorksheetFunction.Match(Target.Interior.color, couleurs, 0) Mod 3)
    Cancel = True
    Exit Sub

color:
    Target.Interior.color = couleurs(0)
    Target.Font.color = couleurs(0)
    Target.Value = nbre(0)
    Cancel = True
End Sub

Bye !

Bonjour

Excellent

Exactement ce que je souhaitais.

En fait je suis sur la gestion de planning. Du coup en fonction de la couleur et de sa valeur, je peux y affecter des tas de formules.

Donc merci beaucoup

Re bonjour

Question Ultime

Que rajouter dans le code pour que ceci ne soit appliquable que sur une zone de ma feuille, genre Colonne J à Colonne Z

Merci pour vos retours. Ne vous prenez pas la tête sur ce sujet, ce n'est pas vital.

Bonne journée

Bonjour

Essaie ça :

Private Sub Worksheet_BeforeDoubleClick(ByVal Target As Range, Cancel As Boolean)
    If Not Intersect(Target, Range("J:Z")) Is Nothing Then
        Dim couleurs(), nbre(), couleur
        couleurs = Array(RGB(87, 62, 194), RGB(0, 134, 61), RGB(255, 255, 255))
        nbre = Array(1, 2, 3)
        On Error GoTo color
        couleur = couleurs(Application.WorksheetFunction.Match(Target.Interior.color, couleurs, 0) Mod 3)
        Target.Interior.color = couleur
        Target.Font.color = couleur
        Target = nbre(Application.WorksheetFunction.Match(Target.Interior.color, couleurs, 0) Mod 3)
        Cancel = True
    End If
    Exit Sub

color:
    Target.Interior.color = couleurs(0)
    Target.Font.color = couleurs(0)
    Target.Value = nbre(0)
    Cancel = True
End Sub

Bye !

Hello

Merci encore pour votre aide

Le résultat attendu est là.

Je peux mettr een pratique dans mon fichier.

Je partagerai une fois finalisé, histoire que vous compremier l'intérêt

Bonne soirée