Copier si bouton manquant

Bonjour,

Je viens vers vous pour trouver une solution à mon problème de boutons.

J'ai 2 feuilles la Feuil1 qui contient l'information à présenter et la Feuil2 qui sert de copie de sécurité en cas où un bouton serait effacer et qu'il faudrait le copier de la Feuil2 à la Feuil1 au mème endroit qu'il est sur la Feuil2.

J'ai créé un macro pour cela qui est censé vérifier s'il y a parmi les 4 boutons un qui est manquant et si oui il prend le bouton sur la Feuil2 et le copie au mème endroit sur la Feuil1; mais le test ne fonctionne pas.

Alors merci pour votre temps,

Oiseau bleu

bonjour Oiseaubleu,

un essai

Sub Mes_Boutons()
     Dim shS, shD, shp, shp0, c
     Set shS = Sheets("Feuil2")              'Source
     Set shD = Sheets("Feuil1")              'Destination
     arr = Array("Retour", "Enregistrer", "Recuperer", "Effacer")     'ces 4 boutons

     For Each btn In arr
          On Error Resume Next
          Set shp = Nothing
          Set shp = shD.Shapes(CStr(btn) & "btn")

          If shp Is Nothing Then
               Set shp0 = shS.Shapes(CStr(btn) & "btn")     'bouton original
               Set shp = shp0.Duplicate      'copie
               On Error GoTo 0

               If shp Is Nothing Then
                    MsgBox "bouton original n'existe pas", vbCritical, btn
               Else
                    With shp                 'le copie
                         .Name = shp0.Name   'renommer
                         .Cut
                         shD.Paste           'déplacer
                    End With

                    With shD.Shapes(CStr(btn) & "btn")     'copie déplacée
                         .Top = shp0.Top     'même position que l'original
                         .Left = shp0.Left
                    End With
               End If
          End If
     Next

     On Error GoTo 0
     Application.CutCopyMode = False
     Application.Goto ActiveCell

End Sub

Bonjour et merci pour votre retour.

Les variables arr et btn ne sont pas définis. Tu les définiraient comment ? range, variant ?

Merci,

Oiseau bleu

re, les 2 sont variant

  Dim shS, shD, shp, shp0, c, Arr, btn
 

Merci beaucoup pour votre retour cela fonctionne à merveilles je vais l'intégrer à mon fichier réel et voir comment cela se comporte.

Merci encore à vous.

Oiseau bleu