Automatiser une lettre de colonne dans une formule
Bonjour :D
Je vous explique mon cas :
J'aimerais pouvoir déduire, dans un onglet "Tache" la "date de fin" (colonne "P") d'une tâche, en fonction d'une "date de début" (colonne "O") et de la personne à qui elle est attribuée (colonne "L").
Ceci prenant en compte les éventuels congés de la personne (congés qui sont renseignés dans un autre onglet "Congés")
Aujourd'hui, j'ai la formule qui permet de faire ça,
=SERIE.JOUR.OUVRE.INTL(O5;M5;;Congés!B$4:B$152)Mais je suis obligé de modifier "manuellement" la lettre de la colonne correspondant à la personne assignée (ici "B").
Lettre qu'on retrouve dans l'onglet "Congés"
J'aimerais donc pouvoir automatiser ça dans ma formule.
J'ai trouvé divers solutions pour remplacer le texte Congés!$B4:$B100 de façon dynamique :
D'abord, en attribuant un nom à ma plage de congés (nomPlage = "Paul" pour la plage Congés!B4:B100) puis en prenant en référence la cellule où est indiqué le nom de ma plage (cellule L5 de mon onglet "Tache").
Ce qui donnerait :
=SERIE.JOUR.OUVRE.INTL(O5;M5;;L5) Mais quand je fais ça, j'ai pour tout résultat #VALUE! au lieu d'une date attendue. De plus, cette méthode a l'inconvénient de m'obliger à modifier les noms de plages à chaque fois que j'ai besoin de changer de personne (ce qui arrive souvent sur une année, car j'utilise ca pour des projets de 2 ou 3 mois. Tous les 2 ou 3 mois, je me retrouve donc à devoir modifier PAUL, LUC, ANNE dans mon onglet "Congés" et donc à modifier le nom de ma plage
J'ai aussi essayé une autre méthode qui me conviendrait plus, via la formule =CONCATENER ou simplement en concaténant.
Ce qui donnait :
=SERIE.JOUR.OUVRE.INTL(O11;M11;;"Congés!"&K5&"$4:"&K5&"$100") ou alors
=SERIE.JOUR.OUVRE.INTL(O11;M11;;=CONCATENER("Congés!";K5;"$4:";K5;"$100") ) K5 étant la cellule qui reprend le lettre de la colonne correspondant à la personne. Elle est récupérée depuis l'onglet "Congés", Ligne 1 via la formule
=SUBSTITUE(ADRESSE(1;COLONNE();4);"1";"")Mais là encore, j'obtiens #VALUE! au lieu d'une date attendue
Pourtant, quand je rentre tout simplement =CONCATENER("Congés!";K5;"$4:";K5;"$100") ou ="Congés!"&K5&"$4:"&K5&"$100" dans une cellule vide, j'obtiens bien le texte Congés!B$4:B$100 que je cherche à dynamiser (voir Cellules F14 et F15 de mon fichier)
Mais dès lors que je cherche à insérer autre chose que le texte pur et dur dans =SERIE.JOUR.OUVRE.INTL(O5;M5;;ICI), ca me met #VALUE ....
Donc :
=SERIE.JOUR.OUVRE.INTL(O11;M11;;Congés!B$4:B$100)= FONCTIONNE
="Congés!"&K5&"$4:"&K5&"$152"dans une cellule vide = Congés!B$4:B$152 (donc c'est bien ce que je cherche à obtenir, dans ma formule)
Mais dès que je l'insère dans la formule :
=SERIE.JOUR.OUVRE.INTL(O11;M11;;"Congés!"&K5&"$4:"&K5&"$100")= #VALUE!
Bonsoir,
avez-vous essayé avec INDIRECT ?
Congés!B$4:B$152 = INDIRECT("Congés!" & $K$5 & "$4:" & $K$5 & "$152")
@ bientôt
LouReeD
C'est toujours quand la solution est devant soi qu'on ne la voit pas :D
Ceci a bien réglé mon problème de #VALUE!
C'est super merci beaucoup beaucoup !!
Mais du coup je me rends compte que la valeur de cellule K5 (la Lettre "B" dans mon exemple) n'est pas récupérée automatiquement, je l'avais mise à la main.
Quelqu'un saurait comment je pourrais récupérer cette lettre automatiquement ?
J'ai réussi à le faire dans l'onglet "Congé", mais dans une cellule qui se trouve dans le même onglet et dans la même colonne.
Là, il faudrait donc que j'arrive à récupérer en K5 de l'onglet TACHES, la lettre de la Colonne (dans l'onglet Congés) correspondant au nom indiqué en L5 de l'onglet TACHES
Bonsoir,
formule en P5, il n'y a plus besoin de K5 !
=SERIE.JOUR.OUVRE.INTL(O5;M5;;INDIRECT("Congés!L5C"&EQUIV(L5;Congés!3:3;0)&":L152C"&EQUIV(L5;Congés!3:3;0);FAUX))
@ bientôt
LouReeD
LouReeD un IMMENSE merci !
Je suis dessus depuis vendredi et je n'arrivais pas trouver la bonne solution !
Je n'étais pourtant pas trop trop loin, car j'utilisais les bonnes formules, mais impossible de trouver la bonne syntaxe si bien que je pensais ne pas avoir els bonnes formules, en fait.
Merci merci merci.
Je peux fermer le sujet et espérer que cela aidera d'autre personnes :D