Ajouter +1 à une cellule par rapport à la précédente

Bonjour !

Je tiens à m'excuser d'avance si le sujet semble évident ou facile... J'ai beau fouiller notre amis google, je n'arrive pas à trouver ou comprendre la mécanique derrière tout ça..

Voici mes quelques lignes :

Private Sub valider_Click()
Sheets("Liste Facture").Activate
Range("A2").Select
Selection.End(xlDown).Select 'SELECTION DERNIERE LIGNE DU TABLEAU
Selection.Offset(1, 0).Select 'SELECTION LIGNE SOUS TABLEAU
End Sub

J'essai d'apprendre tout en construisant mon fichier. Avant de continuer mon projet qui doit commencer dans ma colonne 2, j'aimerai copier ma dernière ligne de mon tableau (ici A21) et le coller en A22 en ajoutant 1 à la valeur et ainsi de suite de suite à chaque fois que j'exécuterai la macro.

Pouvez-vous m'apprendre et me donner la petite solution de cela s'il vous plait ?

Merci

Bonjour uca50,

Une question, pourquoi vouloir utiliser VBA alors qu'une formule peut suffire

A+

Bonjour Bruno

Je cherche a monter en compétence petit à petit

J'utilise VBA parce que j'ai appris a créer un formulaire pour compléter ce tableau, du coup quand je clique sur valider il suit la procédure... mais je sais pas et je trouve pas la solution pour ajouter +1 a la cellule précédente pour finaliser ce petit projet

Merci de ta réponse

Bonjour,

Une petite aide s'il vous plait ?

J'ai oublie de préciser hier que je passe par un Userform, c'est aussi pour ca que je sollicite votre aide

MErci

Re,

A+

Voici mon fichier

Pour la macro faut juste aller sur formulaire, une entrée sur prestation 1 et valider, la demande en découle par la suite

Re,

Alors cela commence mal, quand j'ouvre votre fichier

Petit rappel légal : La numérotation des factures doit contenir un numéro unique, basé sur une séquence chronologique continue

Ce qui n'est pas le cas dans votre fichier

Comment voulez-vous attribuer un numéro correctement ?

Le +1 va finir par retomber sur le 34 qui ne devrait pas exister...

A+

Merci de votre réponse et patiente !

La n'est pas la question, il ne s'agit pas d'un fichier définitif et nominatif a moi même. Désolé, je devais peut être le préciser avant

Cependant c'est à la fin du tableau que j'aimerai que cette série de donnée continue sur cette colonne continue

Merci par avance encore

Re,

En partant du principe que le TS doit être utilisé comme il ce doit = sans ligne vierge

Voici le code qui fonctionne

Private Sub valider_Click()
  Dim Lo As ListObject
  Dim dLig As Long, dNum As String, NewNum As Integer
  ' Avec la feuille
  With Sheets("Liste Facture")
    ' Avec le TS : Tableau Structuré
    Set Lo = .ListObjects("Tableau5")
    ' Ajouter une ligne vierge
    Lo.ListRows.Add AlwaysInsert:=True
    ' Dernière ligne vierge (normalement)
    dLig = Lo.HeaderRowRange.Row + Lo.DataBodyRange.Rows.Count - 1
    ' Dernier numéro de facture
    dNum = Lo.DataBodyRange.Cells(dLig - 1, 1)
    If dNum = "" Then
      MsgBox "il y a un souci avec votre tableau liste de facture" & vbCr _
      & "Supprimez la/les lignes vides", vbCritical, "OUPS..."
      Stop
    End If
    ' Nouveau numéro = dernier + 1
    NewNum = Right(dNum, 4) + 1
    ' Remplir le TS
    With Lo.DataBodyRange
      .Cells(dLig, 1).Value = "FNN_" & Format(NewNum, "0000")
      .Cells(dLig, 2).Value = P1.Value
      .Cells(dLig, 4).Value = P2
      .Cells(dLig, 6).Value = P3
      .Cells(dLig, 9).Value = MP1
      .Cells(dLig, 10).Value = CDate(txdate)
      .Cells(dLig, 11).Value = Civillité
      .Cells(dLig, 12).Value = nom
      .Cells(dLig, 13).Value = prenom
      .Cells(dLig, 14).Value = adresse
      .Cells(dLig, 15).Value = Val(cp)
      .Cells(dLig, 16).Value = ville
    End With
  End With
  P2 = "-": P3 = "-": adresse = "": nom = "": prenom = "": ville = "": cp = ""
End Sub

A+

Merci beaucoup Bruno

Merci d'avoir mis les commentaires, ca sera plus facile pour que je m'adapte sur l'autre fichier ! C'est un petit détail mais qui va beaucoup m'aider !

Encore désolé pour la petite erreur de la séquence chronologique continue

Merci !