Afficher une liste des categories Outlook Calendars dans un combobox Excel

Bonjour Forum,

je cherche à avoir la liste des categories (couleurs) d'un calendrier outlook dans une combobox de userform excel.

J'arrive à aller le chercher dans un MsgBox, mais .. je ne trouve pas la méthode pour la lister dans une combobox

Private Sub Categories()
Dim ol As Outlook.Application
Set ol = New Outlook.Application
 Dim olobjNameSpace As Namespace
 Dim olobjCategory As Category
 Dim olstrOutput As String

 Set olobjNameSpace = ol.GetNamespace("MAPI")

 If olobjNameSpace.Categories.Count > 0 Then

 For Each olobjCategory In olobjNameSpace.Categories

 olstrOutput = olstrOutput & olobjCategory.Name & vbCrLf
 Next
 End If

 MsgBox olstrOutput

 Set olobjCategory = Nothing
 Set olobjNameSpace = Nothing

Merci

Bonjour crackwood01,

Je te propose d'aménager ta macro '' de la façon suivante :

Sub Categories(ByRef zCategories() As String)
Dim ol As Outlook.Application
Set ol = New Outlook.Application
 Dim olobjNameSpace As Namespace
 Dim olobjCategory As Category
 Dim olstrOutput As String

 ReDim zCategories(0)
 Dim lNb As Long

 Set olobjNameSpace = ol.GetNamespace("MAPI")

 If olobjNameSpace.Categories.Count > 0 Then

     For Each olobjCategory In olobjNameSpace.Categories
        ReDim Preserve zCategories(lNb)
        zCategories(lNb) = olobjCategory.Name
        lNb = lNb + 1
        'olstrOutput = olstrOutput & olobjCategory.Name & vbCrLf
     Next
 End If

 'MsgBox olstrOutput

 Set olobjCategory = Nothing
 Set olobjNameSpace = Nothing
 End Sub

et dans le code d'initialisation du userform, d'ajouter :

Private Sub UserForm_Initialize()
    Dim aCategories() As String
    Dim i As Long

    Categories aCategories()

    Me.cmbCategories.List = aCategories() 'Adapter le nom de la combo

End Sub

Super merci beaucoup!

Je passe ce sujet en résolu!