Afficher prénom d'après initiales si filtre tri activé
Bonjour,
Pour le fichier ci-joint, j'ai une colonne "Artisan" qui regroupe une 100aine de personnes (j'ai réduit le fichier pour l'occasion) identifiées par des initiales.
Je souhaiterais que lorsque le filtre artisan est activé pour un seul artisan, et uniquement dans ce cas, la cellule "Détail" affiche le nom complet de l'artisan.
Si le filtre est activé pour plusieurs personnes, ne rien afficher.
Je suppose qu'il faut créer une table ou un index mais je n'arrive pas au résultat que je souhaite.
Si quelqu'un a la gentillesse de m'aider, merci
Bonjour,
Je t'ai fait une formule pour réaliser ça :
=SI(NB.SI.ENS($A$7:$A$64;INDEX($A$7:$A$64;EQUIV(1;$J$7:$J$64;0);1);$J$7:$J$64;1)=SOUS.TOTAL(3;A7:A64);RECHERCHEV(INDEX($A$7:$A$64;EQUIV(1;$J$7:$J$64;0);1);'Index Prénoms'!$A$1:$B$4;2;FAUX);"")
que je combine avec une colonne supplémentaire qui regarde si la ligne est filtrée ou non, et renvoie 0 si c'est le cas.
Si tu filtres sur un seul artisant, ça t'affichera bien son prénom au complet, sinon la cellule sera vide, la formule est dans la cellule en jaune.
Le test que je fais, c'est de regarder si le nom de l'artisant de la première ligne qui contient un 1 (qui n'est pas filtrée), est le seul nom qui apparait encore dans la liste, en comparant le nombre de noms qui sont identiques à celui de cette ligne, et le nombre total de noms non filtrés, si les valeurs sont identiques (un seul nom), alors ça va rechercher ce nom dans l'autre feuille pour avoir le prénom au comple,t sinon la formule renvoie "".
Je te passe le fichier ici:
Un grand merci à toi.
Je ne pensais pas que la formule serait aussi complexe mais je comprends en la décryptant (du coup je découvre d'autres Fx que je ne connaissais pas !
La colonne supplémentaire pour vérifier si le filtre est activé m'embête un peu mais j'imagine qu'il n'y a pas d'autres solution pour voir l'état du filtre (activé ou non).
Merci d'avoir pris le temps en tous cas
Wahou !! tu as bien fait de crier Ausecour sur ce truc, chapeau l'artiste !
Merci à vous deux pour ces retours positifs
Malheureusement je n'ai pas vraiment d'autres idées pour faire ça sans la colonne en plus, enfin tu peux toujours la grouper pour la masquer temporairement, la fonction soustotal n'a pas de fonction NB.SI malheureusement...
En effet, j'avais quand même un peu fouiné avant de poser la question et le sous-total semble être réduit à sa plus simple expression.
Merci tout de même parce que je n'aurais jamais trouvé cette formule tout seul.
Bonjour,
La colonne supplémentaire pour vérifier si le filtre est activé m'embête un peu mais j'imagine qu'il n'y a pas d'autres solution pour voir l'état du filtre (activé ou non).
Sans la colonne supplémentaire, mais avec 2 cellules pour alléger la formule qui serait très lourde sans ça.
En C2, une formule matricielle à valider par Ctrl+Maj+Entrée :
=INDEX(A1:A64;MIN(SI(SOUS.TOTAL(3;DECALER(A7:A64;LIGNE(A7:A64)-7;;1))<>0;SOUS.TOTAL(3;DECALER(A7:A64;LIGNE(A7:A64)-7;;1))*LIGNE(A7:A64))))cette formule renvoie le premier nom de la table, qu'elle soit filtré (filtre multiple ou non) ou pas.
Puis en C3 :
=SI(NB.SI(A7:A64;C2)=SOUS.TOTAL(3;A7:A64);RECHERCHEV(C2;'Index Prénoms'!A1:B4;2;FAUX);"")Celle-ci teste s'il y a bien un filtre unique sur le nom et, dans ce cas, renvoie le résultat.
A+