Lien dans hypertexte dans le corps de mail

Le 11/03/2016 à 09:42

Bonjour à tous,

Je suis en pleine finalisation d'un projet sous VBA.

Je débute dans ce domaine, après avoir parcourus plusieurs forum je me retrouve dans une impasse.

J'ai essayer plusieurs exemple mais sans succès je n'arrive pas a inséré un lien hypertexte dans mon envoie de mail.

Je m'explique, pour le moment j'envoie le fichier complet par mail ce qui me gène un peut car fichier un peut lourd et les macros sont pas forcément pris en compte par tous le monde.

Je voudrais remplacer ce code par quelque chose de plus simple.

Sub SendMailData()

Dim Fichier As String
Dim MonOutlook As Object
Dim MonMessage As Object
Dim MyBench As String

Fichier = "H:\SERVICE\MAINTENANCE PREVENTIVE\Archivage fiche d'intervention maintenance\Fichier excel\Archivage fiche d'intervention maintenance"
ThisWorkbook.SaveAs Fichier

MyBench = Sheets("Fiche d'intervention").Range("I10").Value

  Set MonOutlook = CreateObject("Outlook.Application")
  Set MonMessage = MonOutlook.createitem(0)
  MonMessage.To = "romain.dehan@poclain.com"
  MonMessage.cc = ""
  MonMessage.Attachments.Add "H:\SERVICE\MAINTENANCE PREVENTIVE\Archivage fiche d'intervention maintenance\Fichier excel\Archivage fiche d'intervention maintenance.xlsm"
  MonMessage.Subject = "Demande d'intervention maintenance"
  ' Le corps du message est divisé en 2 lignes :
  Corps = "Bonjour Christophe,"
  ' Chr(13) & Chr(10) = Touche ENTER
  Corps = Corps & Chr(13) & Chr(10)
  Corps = Corps & Chr(13) & Chr(10)
  Corps = Corps & "Ci-joint la demande d'intervention pour le banc : " & MyBench & "."
  MonMessage.body = Corps
  MonMessage.send

  Set MonOutlook = Nothing
Workbooks("Archivage fiche d'intervention maintenance").Close False

End Sub

Je voudrais garder l'envoie du mail le corps de texte les personnes en copies, mais supprimer la pièces jointes.

Mais mettre dans le corps du mail un lien pour y accéder.

Ci joint le classeur, une interface va s'ouvrir pour avoir accès au classeur "faire accès maintenance" puis "Romain Dehan" et entrer en MDP "940606"

https://www.fichier-xls.fr/2016/03/11/archivage-fiche-d-intervention-maintenance/

Le 11/03/2016 à 15:52

bonjour,

pour pouvoir mettre un hyperlien dans ton message il faut envoyer un message au format HTML et mettre les balises qui vont bien(a href).

Je t'ai mis à titre d'exemple un lien vers le fichier que tu ne voulais plus joindre comme annexe.

Sub SendMailData()

Dim Fichier As String
Dim MonOutlook As Object
Dim MonMessage As Object
Dim MyBench As String

Fichier = "H:\SERVICE\MAINTENANCE PREVENTIVE\Archivage fiche d'intervention maintenance\Fichier excel\Archivage fiche d'intervention maintenance"
ThisWorkbook.SaveAs Fichier

MyBench = Sheets("Fiche d'intervention").Range("I10").Value

  Set MonOutlook = CreateObject("Outlook.Application")
  Set MonMessage = MonOutlook.createitem(0)
  MonMessage.BodyFormat = 2
       corps = "<HTML><BODY>"
         MonMessage.To = "romain.dehan@poclain.com"
  MonMessage.cc = ""
'  MonMessage.Attachments.Add "H:\SERVICE\MAINTENANCE PREVENTIVE\Archivage fiche d'intervention maintenance\Fichier excel\Archivage fiche d'intervention maintenance.xlsm"
  MonMessage.Subject = "Demande d'intervention maintenance"
  ' Le corps du message est divisé en 2 lignes :
 corps = corps & "Bonjour Christophe,"
  ' <p> = Touche ENTER
 corps = corps & "<p>"
   corps = corps & "<p> Ci-joint la demande d'intervention pour le banc : " & MyBench & ".</p>"
  corps = corps & "<p><a href=""H:\SERVICE\MAINTENANCE PREVENTIVE\Archivage fiche d'intervention maintenance\Fichier excel\Archivage fiche d'intervention maintenance.xlsm"">lien vers le document</a></p>"
  corps = corps & "</BODY></HTML>"
  MonMessage.htmlbody = corps
  MonMessage.display

  Set MonOutlook = Nothing
Workbooks("Archivage fiche d'intervention maintenance").Close False

End Sub
Le 14/03/2016 à 08:40

Merci ceci fonctionne parfaitement.

Je n'aurais jamais penser a passer par du HTML.

Cordialement

Romain

Rechercher des sujets similaires à "lien hypertexte corps mail"