Copier-Coller et générer PDF

Bonjour chers tous.

En plus de mon problème sur Intersect fait bizarre me revoici avec un autre problème qui semble léger de prime à bord. En effet,

J'ai construit un tableau pour générer les carte de Membres de notre Association. Il y a une BDD où sont stockées les infos des Membres, une autre feuille qui fabrique les carte Membre (une sorte de moule) et une dernière feuille qui récupère la Carte de Membre fabriquée.

Mon Problème est le suivant :

Je Souhaiterais écrire une macro qui va boucler sur chaque membre, Générer sa carte Membre, puis copier et coller la Carte Membre dans la feuille qui récupère les cartes, les une au-dessus des autres, à l'issue du processus, enregistre cette page (des cartes générées) en PDF

Merci !!!!

Fichier joint.

Bonjour,

Testes ceci pour voir :

Sub Test()

    Dim PlgMembre As Range
    Dim PlgCarte As Range
    Dim Cel As Range
    Dim Fichier As String
    Dim Lig As Long
    Dim Espace As Integer

    'défini la plage sur la colonne A de la feuille "Membres de l'association" à partir de A5
    With Worksheets("Membres de l'association"): Set PlgMembre = .Range(.Cells(5, 1), .Cells(.Rows.Count, 1).End(xlUp)): End With

    'le pdf sera dans le même fichier que le claseur
    Fichier = ThisWorkbook.Path & "\Cartes de membres.pdf"

    'une ligne sépare les cartes
    Espace = 1

    'on commence à la ligne 1
    Lig = 1

    With Worksheets("Modèle Carte Membre")

        Set PlgCarte = .Range("A7:F18")

        For Each Cel In PlgMembre

            .Range("C9").Value = Cel.Value

            PlgCarte.Copy Worksheets("Cartes Membres Générées").Cells(Lig, 1)

            Lig = Lig + PlgCarte.Rows.Count + Espace

        Next Cel

    End With
    Worksheets("Modèle Carte Membre").Range("C9").Value = ""

    'crée le pdf et l'ouvre pour contrôle
    Worksheets("Cartes Membres Générées").ExportAsFixedFormat xlTypePDF, Fichier, , True, , , , True

End Sub

OK Merci je te reviens

Bonjour, Testes ceci pour voir

C'est Parfait, Merciiiiiiii

Content de t'avoir aidé

Merci pour tout !

STP, jai un dernier souci sur le Problème d'hier

Theze

Voici le lien ---> https://forum.excel-pratique.com/viewtopic.php?f=2&t=131558

Merci d'avance

Va voir, c'est fait !

J'ai vu ton code que voici

Private Sub Worksheet_SelectionChange(ByVal Target As Range)

    Application.EnableEvents = False

    If Not Intersect(Target, Range("A2:A5")) Is Nothing Then Target.Offset(, 1).Select
    If Not Intersect(Target, Range("D2:F2,H2:K2")) Is Nothing Then Target.Offset(1).Select

    Application.EnableEvents = True

End Sub

Merci !

Mais cela ne suffit pas ! STP, je voudrais que mêmes les autres cellules blanches soient rejetée au clic, est-ce possible ?