Comparer et colorer des cellules de différentes colonnes

Bonjour et d'avance merci pour l'aide que vous m'apporterez.

Je suis en train d'améliorer un fichier excel permettant de valider des lectures pour un challenge.

Je souhaiterais que les cellules catégories potentielles se colorent en rouge si leur nombre est égal à l'une des cellules de la colonne catégorie validée. (voir screen)

Ainsi, les cellules concernées sont de I11 à S11 jusqu'à I111 à S111. Je souhaiterais les comparer aux différentes cellules T11 à T111.

Sur le screen ci-dessous, la cellule I11 devrait se colorer en rouge puisque le nombre 30 se retrouve en T11 et la cellule L11 devrait alors se colorer en rouge puisque le nombre 20 est retrouvé en T12.

Si quelqu'un a une solution car je ne trouve pas la formule à appliquer.

Merciiiii

Cécile

Bonjour et bienvenue sur le forum

Tu devrais joindre ton fichier car on ne peut rien faire sur une image...

Bye !

Ah pardon, je pensais faire les modifications moi-même. Je vous le joins.

Un essai à tester. Te convient-il ?

Option Explicit

Dim tablo, dico As Object
Dim i&, j&

Sub Valider()

    tablo = Range("I11:T" & Range("B" & Rows.Count).End(xlUp).Row)
    Set dico = CreateObject("Scripting.Dictionary")

    For i = 1 To UBound(tablo, 1)
        If tablo(i, UBound(tablo, 2)) <> "" Then
            dico(tablo(i, UBound(tablo, 2))) = ""
        End If
    Next i
    Range("I11:S" & Range("B" & Rows.Count).End(xlUp).Row).Interior.ColorIndex = xlNone

    For i = 1 To UBound(tablo, 1)
        For j = 1 To UBound(tablo, 2) - 1
            If dico.exists(tablo(i, j)) Then
                Cells(i + 10, j + 8).Interior.Color = RGB(255, 0, 0)
            End If
        Next j
    Next i
End Sub

Bye !

C'est génial, merci beaucoup ! Je n'aurais pas pensé qu'il faille passer par un "bouton".

Et pour le coup, je n'aurais jamais trouvé ça toute seule. A moins de suivre un cours de programmation :p

Je n'aurais pas pensé qu'il faille passer par un "bouton".

On n'est pas obligé d'y passer. En validant unenouvelle valeur dans tes colonnes i à s, tu obtiens la même chose.

Bye !