Erreur 1004 - Erreur définie par l'application ou par l'objet

Bonjour,

J'ai suivi un tuto pour créer un gestionnaire d'inventaire. Je ne pensais pas avoir fait d'erreur vu que je l'ai suivi plus ou moins à la lettre, cependant, je rencontre ce message d'erreur.

Voici tout le code!

Private Sub CommandButton1_Click()

Dim DL As Integer

If Me.Txt_Produit <> "" And Me.Txt_description <> "" And Me.Txt_cout <> "" And Me.Txt_prix <> "" And Me.Txt_Quantité <> "" Then

    Sheets(1).ListObjects(1).ListRows.Add
    DL = Sheets(1).Range("b9999").End(xlUp).Row

    'ajouter dans le tableau
    Sheets(1).Range(B & DL) = Me.Label_info.Caption
    Sheets(1).Range(C & DL) = Me.Txt_Produit
    Sheets(1).Range(D & DL) = Me.Txt_description
    Sheets(1).Range(E & DL) = CCur(Me.Txt_cout)
    Sheets(1).Range(F & DL) = CCur(Me.Txt_prix)
    Sheets(1).Range(G & DL) = CInt(Me.Txt_Quantité)
    Sheets(1).Range(O & DL) = "Active"

    Sheets(2).Range("d19") = Sheets(2).Range("d19") + 1

    ThisWorkbook.Save

    Unload Add_produit

End If
End Sub
------------------------------------------------------------------------------------------------------------------------
Private Sub Txt_cout_Change()

' uniquement des chiffres
If Not IsNumeric(Txt_cout) And Txt_cout <> "" Then
    MsgBox "Ne peut contenir que des chiffres"
    Txt_cout = ""

End If
End Sub
------------------------------------------------------------------------------------------------------------------------------
Private Sub Txt_prix_Change()

' uniquement des chiffres
If Not IsNumeric(Txt_prix) And Txt_prix <> "" Then
    MsgBox "Ne peut contenir que des chiffres"
    Txt_prix = ""

End If
End Sub
-----------------------------------------------------------------------------------------------------------------------------
Private Sub Txt_Quantité_Change()

' uniquement des chiffres
If Not IsNumeric(Txt_Quantité) And Txt_Quantité <> "" Then
    MsgBox "Ne peut contenir que des chiffres"
    Txt_Quantité = ""

End If
End Sub
------------------------------------------------------------------------------------------------------------------------------
Private Sub UserForm_Initialize()

Me.Label_info.Caption = Sheets(2).Range("e19").Value

End Sub

Merci de votre aide!

Bonsoir Kenny Nicolas,

Ce n'est pas parce que l'on inscrit une colonne en majuscule que l'on peut se dispenser des guillemets.

'ajouter dans le tableau
    Sheets(1).Range(B & DL) = Me.Label_info.Caption

Idem pour les Range suivants du tableau. Donc Range("B" & DL).

Merci pour la réponse!

Je me disais bien que ça devait être une bêtise! ^^

suite,

plutôt une étourderie... En recopiant trop vite.

Merci de clore le sujet si cela te convient.