Les valeurs les plus proches

Bonjour à tous,

J’utilise cette formule pour trouver la valeur la plus proche

=MIN(SI(ABS(H4:H14-B1)=MIN(ABS(H4:H14-B1));H4:H14))

Mon souhait serait de pouvoir trouver aussi le second le troisième …………. les valeurs les plus proche.

Merci de votre aide

Bonjour,

En B2 à valider avec CTRL + SHIFT + ENTREE, puis à tirer vers le bas

=MAX(SI($H$4:$H$14<$B1;$H$4:$H$14))

Cdlt

Bonjour Arturo ,

Merci de votre réponse.

Je ne parviens pas à étendre cette formule pour obtenir le 2-ème plus proche, le 3-ème plus proche.

Sur la finalité j’aimerais classer l’ensemble des donner H4:H14 au plus proche de B1 dans la section B2 :B12 .

Cdt

Avec le fichier joint, n'est-ce pas ce que vous aviez demandé ?

Oui c’est cela, je n’ai pas bien exprimé ma demande.

Car j’aimerais que le nombre positif dans cette exemple le 555 ce place en 3 position.

Pour avoir un classement comme suis au plus proche de 500.

465

455

555

652

752

135

841

125

Avec une colonne intermédiaire en G qui calcule la différence entre la valeur de référence et la liste des valeurs à classer en H.

En colonne G les différences:

=ABS($B$1-H2)

En colonne B,

=INDEX($G$2:$H$12;EQUIV(PETITE.VALEUR($G$2:$G$12;LIGNE()-1);$G$2:$G$12;0);2)

Cdlt

Super !! Merci pour ce travail

Bonsoir,

Dernière petite requête s’il vous plait.

Si je veux conserver l’association entre la plage valeur et le collaborateur ?

Merci de votre aide.

Cdt

Bonjour,

Normalement, une simple formule RECHERCHEV ferait l'affaire, exemple en C2

=RECHERCHEV($B2;$H$2:$I$13;2;0)

Mais, le problème est que celle-ci ne gère pas les doublons et renverrait toujours le même nom si dans la plage de valeurs à tester il y avait plusieurs fois la même valeur attribuée à des personnes différentes.

Pour que cela, il faut procéder autrement, j'ai ajouté 2 colonnes (vous pouvez les masquer par la suite), qui compte le nombre de valeurs trouvées, ceci permet de distinguer chaque nom et ainsi d'éviter les doublons.

En colonne F, formule qui compte le nombre de fois où la valeur est trouvée dans le tableau de la base de données :

=NB.SI($H$1:$H2;$H2)

En colonne D, formule qui compte le nombre de fois où la valeur est trouvée dans le tableau des résultats:

=NB.SI($B$1:$B2;$B2)

Et enfin la formule qui extrait le nom des collaborateurs en fonction des valeurs associées( Attention formule matricielle, à valider avec CTRL + SHIFT + ENTREE).

=INDEX($F$2:$I$15;EQUIV(1;($F$2:$F$15=$D2)*($H$2:$H$15=$B2);0);4)

Dans le fichier joint, j'ai ajouté des noms qui possédaient la même valeur, on peut voir que dans le tableau de restitution ils sont bien présents, alors que si vous conservez la première formule, vous n'obtiendrez pas ce résultat.

Cdlt

Magnifique travail Arturo

Je ne serais jamais parvenue à le faire sans votre aide.

Bien vue pour les doublons

Je vais pouvoir continuer mon projet !

Merci a vous

Bien Cordialement