Macro export PDF avec sélection dans liste déroulante et segment de TCD

Bonjour à toutes et à tous,

Je ne connais presque rien en macro et j'aurais besoin de votre aide :)

Dans le fichier ci-joint qui nous servira d'exemple, je souhaiterais enregistrer en pdf les tableaux de mes deux onglets. Ce sont deux exemple différents mais il me faudrait une solution pour chacun.

Dans le premier onglet, j'ai un tableau avec une liste déroulante. Il faudrait enregistrer sous pdf cet onglet, puis sélectionner la catégorie suivante dans la liste déroulante et enregistrer un nouveau pdf, et ainsi de suite avec toute la liste. Il faudrait que le nom de ces pdf soit le même que celui de la catégorie sélectionnée avant enregistrement.

Dans le deuxième onglet, c'est exactement la même chose mais en utilisant les segments liés au TCD.

Merci beaucoup pour votre aide !

Edouard

Bonjour,

Un moyen facile d'avoir une début de piste de code est d'utiliser l'enregistreur de macro, faire l'action désirée, et ensuite regarder dans le code les fonctions ou méthodes utilisées pour les adapter à notre sauce.

Bonjour,

Merci du retour mais cette solution ne suffit pas pour mon problème. Enregistrer une macro me permettra de sélectionner quelque chose de précis mais pas d'aller au bout d'une liste.

Edouard

Bonjour,

Ci-contre (pas certain de la compatibilité mac par contre car je ne connais pas cet OS) :

Sub MEF()
Dim REF As Variant, CATE As Variant, SEG As Object, I%, CHEMIN$
CHEMIN = "C:\Users\*****\Desktop\A\" 'A adapter
With Worksheets("TABLEAU")
    For Each REF In Range(.[B3].Validation.Formula1)
        .[B3] = Worksheets("Liste").Range(REF.Address)
        .ExportAsFixedFormat Type:=xlTypePDF, Filename:=CHEMIN & "TABLEAU_" & .[B3]
    Next REF
End With
Set SEG = ActiveWorkbook.SlicerCaches("Segment_CATEG")
With SEG
    .ClearAllFilters
    .SlicerItems(1).Selected = True
    For Each CATE In .VisibleSlicerItems
            If CATE.Name <> .SlicerItems(1).Name Then CATE.Selected = False
    Next CATE
    Worksheets("TCD").ExportAsFixedFormat Type:=xlTypePDF, Filename:=CHEMIN & "TCD_" & .SlicerItems(1).Name
    For I = 2 To .SlicerItems.Count
        .SlicerItems(I * 1).Selected = True
        .SlicerItems(I - 1).Selected = False
        Worksheets("TCD").ExportAsFixedFormat Type:=xlTypePDF, Filename:=CHEMIN & "TCD_" & .SlicerItems(I * 1).Name
    Next I
End With
End Sub

Le chemin d'enregistrement est bien sûr à adapter.

Cdlt,

Bonjour,

Pardon pour la réponse tardive.

C'est parfait, merci beaucoup ! C'est exactement ce qu'il me fallait et les deux solutions fonctionnent très bien !

Un grand merci pour votre aide !

Bonne journée,

Edouard

Rechercher des sujets similaires à "macro export pdf selection liste deroulante segment tcd"