Liste de données à partir d'un tableau
Bonjour le forum,
Je cherche à extraire des données d'un tableau pour créer une liste sans doublons à partir de celles-ci.
J'ai testé plusieurs pistes mais sans succès (fonction UNIQUE, extraction des doublons...)
Ci-joint un fichier test avec un exemple.
Merci d'avance.
Bonjour,
Deux tests, un par DICO (Site de Boisgontier, adapté au besoin), un par array (moins efficient, donc par moi) :
Sub DOUBLONS()
Dim DICO As Object, REF As Range
With Worksheets("Feuil5")
Set DICO = CreateObject("Scripting.Dictionary")
For Each REF In .[D2:J7]
If REF <> "" Then DICO(REF.Value) = ""
Next REF
.[B10].CurrentRegion.ClearContents
.[B10].Resize(DICO.Count, 1) = Application.Transpose(DICO.keys)
.[B10].CurrentRegion.Sort .[B9], xlAscending
End With
End Sub
'<------------------------------------------------------------------------->
Sub DOUBLON()
Dim REF As Range, DOUBLON As Boolean, L&
Dim DOUB()
With Worksheets("Feuil5")
ReDim DOUB(0)
DOUB(0) = .[D2]
For Each REF In .[D2:J7]
DOUBLON = False
For L = LBound(DOUB) To UBound(DOUB)
If REF = DOUB(L) Or REF = "" Then DOUBLON = True: Exit For
Next L
If DOUBLON = False Then
ReDim Preserve DOUB(UBound(DOUB) + 1)
DOUB(UBound(DOUB)) = REF
End If
Next REF
.[B10].CurrentRegion.ClearContents
.[B10].Resize(UBound(DOUB) + 1) = Application.WorksheetFunction.Transpose(DOUB)
.[B10].CurrentRegion.Sort .[B9], xlAscending
End With
End SubCdlt,
Bonjour !
Si vous utilisez la fonction UNIQUE.....votre version Excel intègre donc Power Query.
Je vous livre une proposition utilisant cet outil :
Bonjour Ergotamine,
j'étais plutôt orienté vers une fonction mais le DICO convient parfaitement à ma demande.
Ceci n'était qu'une étape de mon fichier donc je vais certainement devoir l'adapter un peu mais cela m'aide déjà énormément.
je reviendrais vers vous si besoin.
Merci en tout cas pour votre rapidité et efficacité!
Cdlt,
Bonjour JFL,
merci également pour votre réponse.
Du coup cela me donne 2 méthodes! (il ne me reste plus qu'à voir laquelle est la plus adaptée pour la suite de mon projet)
Cdlt,