Récupérer le nom de chaque fichier Excel présent dans un dossier

Bonjour tout le monde, je suis stagiaire et l'on ma demander un travaille que je n'arrive pas du tout. Je dois lire le nom de chaque fichier Excel présent dans une clé USB, je dois aller dans le stockage de la clé, prendre le fichier 1 et l'associer a "nom 1" le fichier 2 a "nom 2" etc, je travaille en langage VB mais sur le logiciel siemens. Merci de votre aide, je ne suis vraiment pas douée en script
voici ce que j'ai essayer de réaliser:

(la première ligne étant pour vérifier que le script se lance bien et écrit correctement a l'écrans)

Bonjour

Ci joint une macro pour t'aider à résoudre ton problème

Sub ListeFichiersRepertoire()
    Dim Repertoire As String, Fichier As String
    Dim Tableau() As Variant
    Dim x As Integer, i As Integer
    Dim VerifTab As Variant

    'Définit le répertoire pour la recherche
    Repertoire = "f:\Documents\"
    'Recherche tous les types de fichiers
    Fichier = Dir(Repertoire & "\*.*")

    'Boucle sur les fichiers pour récupérer les infos
    Do While Fichier <> ""
        'Incrémente le compteur de fichiers
        x = x + 1

        '--- Redéfinit la taille de la dernière dimension du tableau
        ReDim Preserve Tableau(1 To 2, 1 To x)
        '------------------------------------

        'Récupère le nom du fichier
        Tableau(1, x) = Fichier
        'Récupère  la date et l'heure de création ou de dernière modification.
        Tableau(2, x) = FileDateTime(Repertoire & "\" & Fichier)
        Range("A" & x).Value = Tableau(1, x)
        Range("B" & x).Value = Tableau(2, x)

        Fichier = Dir
    Loop

    '--- On vérifie si le tableau est vide
    On Error Resume Next
    'VerifTab va prendre la valeur Empty si le tableau est vide.
    VerifTab = UBound(Tableau)
    On Error GoTo 0

    If IsEmpty(VerifTab) Then Exit Sub
    '---

    'Boucle pour lire le contenu du tableau.
    'UBound(Tableau, 2) permet de récupérer la limite supérieure de la 2eme dimension
    For i = 1 To UBound(Tableau, 2)
        'Inscrit le résultat dans la fenêtre d'exécution (Ctrl+G)
        Debug.Print Tableau(1, i) & " --> " & Tableau(2, i)
    Next i
End Sub

A+ François