Copier et coller uniquement les texte et pas les formule

Bonjour,

Je viens solliciter votre aide, je ne sais pas si je fais bien de créer un autre sujet, car ma question est en relation avec le sujet "Extraire les données d'un tableau dans une feuille par critères". voici le code qui permet l'extraction des données pour pouvoir copier/coller.

Private Sub ComB1_Click()
Dim i%
Dim WS() As Variant
Dim VAL() As Variant

Sheets("Source").Unprotect Password:="3579"
'Définition des variables dans l'ordre dans le tableau WS
WS = Array("Méthodes de Maintenance", "Garage", "Maintenance Centrale", "1er Transformation", "2ème Transformation", "3ème et 4ème Transformation")
'Définition des variables dans le même ordre dans le tableau VAL
VAL = Array("MMaint", "Garage", "MGen", "1erTransfo", "2emeTransfo", "3&4emeTransfo")
'Boucle entre le plus petit index et le plus grand du tableau WS (donc i = 0 à 5 ici)
For i = LBound(WS) To UBound(WS)
'Quand la valeur de la combo box est rencontrée dans le tableau
    If Me.ComboBox1.Value = WS(i) Then
    'Reprend l'indice i, regarde la valeur associée dans le tableau VAL
    'et y place la valeur dans la variable WS_DEST
        WS_DEST = VAL(i)
        'Si pas rencontré alors continue
        Exit For
    End If
'Passe à la valeur suivante de i (donc valeur suivante du tableau WS
Next i
' Si WS_DEST est vide alors affiche message car valeur non trouvée dans WS.
If WS_DEST = "" Then MsgBox "Atelier inexistant dans le tableau": Exit Sub
With Worksheets("Source")
.[A2].CurrentRegion.AutoFilter 1, Me.ComboBox1.Value
    If .AutoFilter.Range.Columns(1).SpecialCells(xlCellTypeVisible).Count - 1 = 0 Then
        .AutoFilterMode = False
        MsgBox "Aucune ligne à extraire", vbCritical
        Exit Sub
        Else
        .AutoFilter.Range.SpecialCells(xlCellTypeVisible).Copy
        Worksheets(WS_DEST).[A1].PasteSpecial
        .AutoFilterMode = False
        MsgBox "Sauvegarde terminée", vbInformation
    End If
    .AutoFilterMode = False
End With

Sheets("Source").Protect Password:="3579"

End Sub

Ce que je voudrais c'est de copier et coller uniquement le texte et non les formules.

Dans la colonne A de la feuille source j'ai une formule qui me permet de reconnaitre les ateliers en fonction du contenu des colonnes B et F.

Lorsque je fais l'extraction la formule est copiée et collée et j'obtiens des cellules avec pour contenue #REF ou des noms d'ateliers incorrectes.

J'ai essayé de modifier le code mais je fait n'importe quoi.

Merci d'avance pour votre aide.

Cordialement

Bonjour,

Sans avoir lu trop votre code dans la logique on mettrait à la place de PasteSpecial qui prend par défaut la valeur xlPasteAll, un xlPasteValues :

Worksheets(WS_DEST).[A1].PasteSpecial xlPasteValues

A tester.

Cdlt,

Bonjour,

ça fonctionne très bien.

Le code ce n'est pas le miens c'est le vôtre ! c'est vous qui m'aviez aidé la première fois.

Quand j'ai essayé de modifier le code, j'avais changé au moins 3 ligne alors qu'il fallait simplement ajouter une seule chose.

Merci !

Cordialement