Aggregate Reporting 2017-2018

Bonjour à tous,

J'espère que vous êtes en SUPER FORME

Je viens à vous, car j'aimerais réaliser la macro suivante :

L'idée serait de créer une boucle pour copier coller le contenu de chaque des pages sur la feuille "Aggregate" les unes en dessous des autres en partant de la feuille "2" jusqu'à la dernière feuille du classeur.

Par exemple, comme j'ai copié la feuille 1 et que je l'ai renommé "Aggregate", si la dernière ligne de la feuille est la 100ème, la macro copie-collera le contenu de la deuxième feuille de calcul à partir de la ligne 101 et ect jusqu'à la dernière feuille de calcul.

En sachant que la première ligne à sélectionner sur chaque feuille est la 5ème en colonne B jusqu'à la colonne M.

Peut-être peut-on préciser à la macro de copier-coller la macro le contenu de B5 à M5 jusqu-à la dernière ligne qui a du contenu.

Je vous remercie par avance pour votre aide et je vous prie de passer une bonne journée.

Amicalement.

Laplacea

Bonjour,

Un test :

Sub SYNTHESE()
Dim L_I%, L_E%, W%, E As Worksheet
Application.ScreenUpdating = False
Set E = Worksheets("Aggregate")
For W = 1 To Worksheets.Count
    With Worksheets(W)
        If .Name <> E.Name Then
            .Range(.Cells(5, 2), .Cells(.Cells(.Rows.Count, 2).End(xlUp).Row, 13)).Copy
            E.Cells(E.Cells(E.Rows.Count, 2).End(xlUp).Row + 1, 2).PasteSpecial xlPasteAll
        End If
    End With
Next W
Application.ScreenUpdating = True
MsgBox "Import terminé", vbInformation
End Sub

A adapter en modifiant xlPasteAll par xlPasteValues si vous ne souhaitez coller que les valeurs.

Probablement possible de l'avoir également par POWER QUERY.

Je ne me suis pas occupé du nettoyage de la feuille Aggregate car non défini dans le besoin, je vous laisse le développer si nécessaire.

Cdlt,

Bonjour à tous,

du pareil au même, mais comme c'est fait...
Il y a un nettoyage en plus

Sub maj()
    Dim sh As Worksheet, nblig As Long
    nblig = Cells(Rows.Count, 2).End(xlUp).Row - 4
    If nblig > 0 Then [B5:M5].Resize(nblig).ClearContents
    For Each sh In Worksheets
        If sh.Name <> "Aggregate" Then
            nblig = sh.Cells(Rows.Count, 2).End(xlUp).Row - 4
            If nblig > 0 Then
                sh.[B5:M5].Resize(nblig).Copy Cells(Rows.Count, 2).End(xlUp).Offset(1)
            End If
        End If
    Next sh
End Sub

Aggregate est sensée être active (bouton dessus)
eric

Bonjour à tous,

Je vous remercie car cela fonctionne super bien ! 😊

A bientôt sur le forum et prenez soin de vous et de vos proches.

Laplacea