Alléger un tableau de calcul de versements de dividende
Bonjour a vous !
j'expérimente toujours sur google Sheets. et je viens de faire un tableau pour visualisé et prédire des versements de dividendes chaque semaines.
actuellement mon tableau est lourd, et beaucoup trop manuel.
si jamais quelqu'un a des idées pour alléger tout ça, je prend :).
par ex. je n'arrive pas a adapter la fonction ARRAY dans mes formules, ce qui allégerai déjà pas mal la chose :)
l'idée etant de faire quelque chose le plus automatisé possible sur cette partie la.
merci a vous !
https://docs.google.com/spreadsheets/d/1m-I5ilRV11kK3gDFKqnXXv-yFoiL5ZqVYeIsZPyvxu4/edit?usp=sharing
par la suite j'aimerai faire une cellule donnant la date du jour, et comme correspondance la somme qui a déjà été versé jusqu'a cette date la en faisant un recherche.
mais je verrais ensuite :)
Bonjour,
en H4, à tirer à droite et en effaçant toutes les formules à partir de la ligne 5
=ARRAYFORMULA(IF($E4:$E="";;IFERROR((DATEDIF(IF(G$3>=$E4:$E;G$3;$E4:$E);H$3;"yd"))*$D4:$D;"")))mieux ... une seule et unique formule en H4
=ARRAYFORMULA(IF(E4:E="";;IFERROR((DATEDIF(IF(G3:AV3>=E4:E;G3:AV3;E4:E);H3:AW3;"yd"))*D4:D;"")))les $ n'étant même plus nécessaires dans ce cas !
Merci ! Je regarde tout ça en débauchant.
Finalement c'était évident sur votre 1ere réponse, une fois sous les yeux bien évidement. Je n'avais pas mis les "$" pour étendre sur la colonne.
Merci encore !
mieux ... une seule et unique formule en H4
=ARRAYFORMULA(IF(E4:E="";;IFERROR((DATEDIF(IF(G3:AV3>=E4:E;G3:AV3;E4:E);H3:AW3;"yd"))*D4:D;"")))
les $ n'étant même plus nécessaires dans ce cas !
Est ce que je peux modifier les valeurs surlignée, de façon a ce que ça me prenne une quantité "illimité" de lignes ? vu que d'autres semaines arriveront il va falloir que je rajoute des colonnes manuellement ( ou automatiquement si possible
bonne journée a vous ! et merci encore
oui, tu peux modifier les colonnes (ce ne sont pas les lignes, mais peut-être que cela va de pair)
en fait, je n'ai pas du tout regardé ta formule ! ma méthode est la suivante, c'est simple en fait
- une fois ta formule établie pour la seule cellule H4 (que je n'ai pas retouchée en elle-même)
- j'ai agrandi les lignes en remplaçant E4 par E4:E et D4 par D4:D
- ensuite j'ai agrandi les colonnes en remplaçant G3 par G3:AV3 et H3 par H3:AW3, sachant qu'il est IMPERATIF d'avoir la même taille de données
- et je me suis dit enfin que les $ étaient inutiles
en faite la formule que vous m'avez donné implique un calcul avec les données présente sur la 1ere ligne entre les colonnes "G" et "AW".
et je vais augmenter ce nombre de colonnes au fils des semaines en faite, donc je voulais savoir si je pouvais pas remplacer ce "AW" par quelque chose qui prendrait directement un nombre "infini" de colonnes par ex.
je vais y réfléchir, mais ce n'est pas évident ... avec INDIRECT, OFFSET ou MMULT
c'est du confort, pas de soucis et surtout pas essentiel :)
je passe le sujet en résolu car le gros du sujet est traité.
merci
Alex, comment on détermine la dernière colonne ? pourquoi aujourd'hui le 27/9/2021 ?
J'ai simplement étiré de façon manuel une date.
Les dividendes tombent tout les lundi. Donc j'ai étiré pour obtenir tout les lundis jusqu'à la fin des colonnes présente.
J'aurais pu en rajouter d'autres, comme en avoir moins à cette instant.
En G3 le début
En G2 le nombre de semaines
En H3 (efface toutes les dates depuis I3 jusqu'au bout) :
=sequence(1;G2;G3+7;7)en H4 :
=ARRAYFORMULA(IF(E4:E="";;IFERROR((DATEDIF(IF(sequence(1;G2;G3;7)>=E4:E;sequence(1;G2;G3;7);E4:E);sequence(1;G2;G3+7;7);"yd"))*D4:D;"")))sequence permet de créer une suite de valeurs
et ... on peut tout mettre en une seule formule en H3
={sequence(1;G2;G3+7;7);ARRAYFORMULA(IF(E4:E="";;IFERROR((DATEDIF(IF(sequence(1;G2;G3;7)>=E4:E;sequence(1;G2;G3;7);E4:E);sequence(1;G2;G3+7;7);"yd"))*D4:D;"")))}avec juste les 2 paramètres en G2 (nombre de semaines) et G3 (date de début)
Oh merci ! je ne connaissais pas ce SEQUENCE.
tout a l'aire ok au niveau de l'intégration et des chiffres :) top !
Merci encore !
j'ai réussi a adapter votre calcul pour mon fichier source !
si je peux abuser de votre temps, j'ai encore un petit point à soulever,
Que je ne parviens pas a résoudre avec Quercy ou une RechercheH avec ma faible expérience ^^'
A partir d'une simple liste crée avec "Validation des données", j'aimerai sortir la somme versée sur une semaine précise. c'est la somme de la colonne qui me pose problème..
je sais trouver la colonne que je veux, je sais trouver des infos individuellement dedans, mais je ne parviens pas à en faire la somme :)
et ensuite je voudrais le total versé entre la date de Début et le dernier versement. ( c'est sur le même model que ma problématique au dessus, donc ensuite je devrais pouvoir y arriver. )
merci encore et bonne soirée
cordialement
alexis
en D2, si j'ai bien compris la première partie
=sum(offset(G6:G;; MATCH(C2;G5:5;0)-1))je regarde pour le cumul
en K2
=sum(offset(G6:G;;;; MATCH(J2;G5:5;0)))avec l'utilisation de offset
OFFSET(référence_cellule, lignes_décalées, colonnes_décalées, [hauteur], [largeur])Top encore une fois ! en revanche je ne veux pas recopier betement vos formules,
=SOMME(DECALER(G6:G;; EQUIV(C2;G5:5;0)-1))
pourriez vous m'expliquer les suite de ";" ?
j'avais ces 3 fonctions individuellement mais je n'arrivais pas a les combiner !
merci encore !
voici les 5 paramètres
référence_cellule, lignes_décalées, colonnes_décalées, [hauteur], [largeur]dans le cas que tu cites ;
- référence :
G6:G - pas de lignes décalées, je ne mets rien (j'aurais pu mettre 0)
- colonnes décalées :
EQUIV(C2;G5:5;0)-1, c'est à dire la recherche de C2 dans la suite des dates, moins 1 sinon je me retrouve une case de plus à droite !
maintenant en K2 : =sum(offset(G6:G;;;; MATCH(J2;G5:5;0))), là j'ai aligné les ; les unes à côté des autres car pas de ligne décalées, pas de colonnes décalées, hauteur sans changement avec la référence G6:G, largeur : le résultat de la recherche