Copie de classeur en valeurs uniquement

Bonjour à toutes et tous,

Je recherche une méthode pour copier/dupliquer un classeur comportant plusieurs feuilles, de façon à ce que la copie ne renseigne automatiquement que les valeurs et non les formules de calcul, et ce afin qu'il puisse être ouvert et lu rapidement sur des postes informatiques d'un certain âge qui ne digèrent pas forcément plusieurs milliers de formules en parallèle.

Merci d'avance et bonne journée

Bonjour,

Avec cette macro à mettre dans un nouveau classeur (à adapter) :

Option Explicit
Sub CopierClasseurValeurs()
Dim wb0 As Workbook
Dim wb1 As Workbook
Dim wsh As Worksheet
Dim rng As Range
Dim nom As String
Dim ext As String
Dim i As Integer

  Set wb0 = Workbooks("Nom du classeur à copier.xlsx")   ' à adapter (doit être ouvert)
  nom = wb0.FullName
  ext = Mid(nom, InStrRev(nom, "."))
  nom = Replace(nom, ext, "") & " - copie"
  If Dir(nom & ext) <> "" Then
    i = 1
    Do While Dir(nom & " (" & i & ")" & ext) <> "": i = i + 1: Loop
    nom = nom & " (" & i & ")"
  End If
  nom = nom & ext
  wb0.SaveCopyAs nom
  Set wb1 = Workbooks.Open(nom)
  For Each wsh In wb1.Worksheets
    Set rng = wsh.UsedRange
    rng.Copy
    rng.PasteSpecial xlPasteValues
  Next
  Application.DisplayAlerts = False
  wb1.Close True
  Application.DisplayAlerts = True
End Sub

Ca fonctionne parfaitement, merci beaucoup