Texte + sellection de cellules dans le corps de mail

Bonjour à tous,

Je suis en train de créer une macro afin d'envoyer un mail à plusieurs destinataires.

Dans le corps de ce mail, je voudrai une introduction qui serait "type" et ne changera jamais, suivi d'une sélection de cellule...

Avec le code que j'ai réussi à compiler, actuellement j'arrive à sélectionner mes cellules, je clique sur un bouton qui me génère le mail via Outlook

Le problème est que je n'arrive pas, en plus de la sélection de cellules, à ajouter du texte dans le "body"

Sub Mamacro()

Dim oOutlook As Object

Set oOutlook = CreateObject("Outlook.Application")

Dim oMail As Object

Set oMail = oOutlook.CreateItem(0)

With oMail

Dim oObjetWord As Object

Set oObjetWord = .GetInspector.WordEditor

.To = "toto@toto.fr;toto2@toto.fr"

.CC = "toto3@toto.fr;toto4@toto.fr"

.Subject = "mon sujet"

.Body = ActiveCell

Selection.Copy

oObjetWord.Range(0).Paste

.Display

End With

End Sub

Merci d'avance pour votre aide

Bonjour, un petit up pour un peu d'aide svp

Je n'y connais rien en VBA, j'ai trouvé ces quelques lignes de code sur le net et j'aurai bien besoin d'aide :-)

Merci d'avance

Bonjour,

.Body = "Ton texte " & ActiveCell & vbCrLf & vbCrLf & " Ton texte"

A noter que tu peux réaliser des sauts de lignes à l'aide de vbCrLf.

Cdlt,

Bonjour Ergotamine et merci pour ton retour

J'avais déjà essayé ce code

le problème c'est que je dois sélectionner un groupe de cellules et que le texte n’apparaît pas dans le corps du mail...

.Body = "Ton texte " & ActiveCell & vbCrLf & vbCrLf & " Ton texte"
Selection.Copy
oObjetWord.Range(0).Paste

J'ai essayé ça

Bonjour,

Je ne comprend pas ... A quoi correspond la sélection ? Une cellule, une plage ? Pourquoi utiliser un objet Word sur un fichier Excel ?

Là encore, il manque beaucoup d'éléments, un fichier exemple avec ce que vous souhaitez envoyer et le résultat attendu.

Cdlt,

"Texte"

Mes cellules sélectionnées sous forme de tableau

"texte"

Bonjour,

Je viens de comprendre, outlook se base sur l'éditeur WORD pour modifier le body des messages. Le body est codé en HTML.

Ci-joint un exemple fonctionnel :

Sub EnvoiMailBHLPN()

Dim oOutlook As Object
Dim oMail As Object
Dim oObjetWord As Object
Dim xHTMLBody As String
Selection.Copy
Set oOutlook = CreateObject("Outlook.Application")
Set oMail = oOutlook.CreateItem(0)
With oMail
     .To = ""
     .CC = ""
     .Subject = "Nouvelle demande d'itération du BHR PN"
     .HTMLBody = "<p>Le texte d'introduction s'inscrit ici : </p> " _
            & "<p>""</p>" _
            & "<p>Cdlt</p>"
     .Display
    Set oObjetWord = oOutlook.ActiveInspector.WordEditor
    Set tblRange = oObjetWord.Range.Paragraphs(2).Range
    tblRange.Paste
End With
End Sub

Les sauts de lignes se font via la balise <br> avant le mot concerné. <p> délimite les paragraphes. Ici le tableau de situe entre le 2ème <p> et </p>, où je colle la sélection dans le Paragraphs(2).Range à la fin de la macro. Si vous ajoutez des <p> n'oubliez pas de changer le paragraphe de collage.

Cdlt,

Effectivement ça fonctionne !!!

Merci infiniment !!

et est-il possible de ne sélectionner que les cellules visibles ? étant donné que certains volets sont figés ?

Merci

Bonjour,

Pas trop compris. Mais si vous filtrez ou masquez les lignes non souhaitée seules les cellules visibles de la sélection sont incorporées dans le mail.

Si par cellules visibles vous voulez insinuer cellules visibles uniquement via l’ascenseur alors je ne crois pas. Ces cellules sont tout de même considérées comme visibles car non masquées dans le sens applicatif du terme.

Donc deux solutions : masquer ou filtrer.

Cdlt,

Edit : D'ailleurs si c'est la scrollbar de droite don on parle, si vous dezoomez sans filtrer ou masquer, vous verrez que les lignes réapparaissent. Elles ne sont pas masquées au sens propre du terme.

Merci encore une fois Ergotamine,
En appliquant un filtre j'arrive au résultat voulu !!

Désolé si mes explications n'étaient pas toujours très claires, pas évident d'expliquer :-p