[Google Sheets] Consolider des onglets

Alors que la logique voudrait que les données soient rassemblés dans une unique "base de données", Goggle Sheets permet néanmoins de consolider des données de plusieurs onglets sans recours à un script ou une macro.

L'avantage est avant tout ergonomique (par exemple dans la tenue de comptes bancaires différents : la dissociation par onglet des différents comptes améliore la lisibilité et le calcul de trésorerie courant). Mais il améliore aussi le travail collaboratif.

Pour appeler les données d'un onglet / d'un compte :

=query('Compte 1'!A2:H;B3)
avec dans B3 ="select H,A,C,D,E,F where A>=DATE'2021-01-01' AND A<=DATE'2021-01-31' "

on collecte ici 6 colonnes de données répondant aux critères de date

Pour appeler les données de plusieurs onglets / plusieurs comptes ( ; permet d'empiler plusieurs résultats, dépend des paramètres régionaux)

={
query('Compte 1'!A2:H;B3);
query('Compte 2'!A2:H;B3);
query('Compte Joint'!A2:H;B3)
}
avec dans B3 ="select H,A,C,D,E,F where A>=DATE'2021-01-01' AND A<=DATE'2021-01-31' "

MAIS, en cas d'absence de résultat à partir de l'un des 3 onglets, c'est toute la formule qui provoque une erreur.

Il faut donc, en cas d'erreur sur un onglet, lui substituer une ligne vierge de 6 colonnes puisque la sélection portent sur 6 colonnes, cette ligne s'écrit comme suit

{""\""\""\""\""\""}

le séparateur \ permettant d'écrire sur la même ligne (dépend des paramètres régionaux)

=iferror(query('Compte 1'!A2:H;B3);{""\""\""\""\""\""})

On pourra ensuite encapsuler le tout par un query pour éliminer ces lignes vierges, ici avec un tri sur la date (colonne A des onglets sources, et Col2 du résultat des queries sur chaque onglet).

={query({
iferror(query('Compte 1'!A2:H;B3);{""\""\""\""\""\""});
iferror(query('Compte 2'!A2:H;B3);{""\""\""\""\""\""});
iferror(query('Compte Joint'!A2:H;B3);{""\""\""\""\""\""})};
"select * where Col1<>'' ORDER BY Col2")
}
avec dans B3 ="select H,A,C,D,E,F where A>=DATE'2021-01-01' AND A<=DATE'2021-01-31' "
Rechercher des sujets similaires à "google sheets consolider onglets"