Comment créer une macro pour sélectionner des données dans des colonnes et

Merci d'avoir pris le temps de travailler avec moi. Je l'apprécie beaucoup beaucoup ...

Comment créer une macro pour sélectionner des données dans des colonnes et des lignes et supprimer les données restantes.Comment créer une macro pour sélectionner des données dans des colonnes et des lignes et supprimer les données restantes.
Transfère ensuite les données dans un nouvel onglet. Ne garder que les dernières dates avec ses données ...

J'ai un problème avec ce classeur que je télécharge sur une base hebdomadaire.

Ses mises à jour hebdomadaires entraînent le déplacement des noms des en-têtes et des noms des lignes dans différentes cellules à mesure que de nouvelles données sont téléchargées.

Ma tâche est de créer une macro pour sélectionner les mots exacts dans certaines colonnes et le groupe exact de mots dans une certaine ligne. Supprimez ensuite le reste des données.

Prochain.

Ensuite, ne prenez que la dernière date avec ses valeurs et en-têtes de chaque groupe de mots et créez un tableau dans une nouvelle feuille de calcul.

Voici un exemple avec les données extraites et leurs valeurs avec ses en-têtes ...

Voici la liste des noms pour créer un tableau dans la nouvelle feuille de calcul ...

veuillez télécharger le classeur ci-dessous...

Si vous le souhaitez, merci pour votre aide.

À votre santé

Ceci est un petit fichier pour le mois de janvier

J'espère que je ne l'ai pas rendu déroutant

Bonjour,

Les spécialistes en Power Truc vont te sortir ça en & petit tour !

A+

Merci aux excellents spécialistes. J'attends gracieusement ta réponse ...

Un peu de patience mon ami ils ne sont pas nombreux, mais ça ne saurai tarder : Le simple fait de remonter le fil de temps en temps va les attirer comme des mouche sur la viande... Il faut dire que ton titre et ta présentation ne sont pas motivants : Si tu sais modifier le titre de ton topic, change le pour "extraction de données pour mise à jour BD."

Rien de tel qu'un bon titre pour motiver le chaland...

A+

Bonjour,

Voici une proposition avec PowerVBA : La macro test s'exécute grâce à un double-clic sur la feuille XLS ou depuis le code.

Il y a pour l'instant une macro secondaire qui supprime la feuille. Elle pourra être désactivée.

Sub test()

Dim textract(), chaine$

Set reg = CreateObject("vbscript.regexp")
motif = Join(Application.Transpose(Range("Liste")), "|")
tdatas = Sheets(1).UsedRange
ReDim textract(1 To UBound(tdatas), 1 To UBound(tdatas, 2))

Call supprimer

For i = LBound(tdatas) To UBound(tdatas)
    reg.Pattern = motif
    chaine = tdatas(i, 1)
    If reg.test(chaine) Then
        lig = match(chaine, textract, 1)
        If lig > 0 Then
            If tdatas(i, 2) > textract(lig, 2) Then
                For k = LBound(tdatas, 2) To UBound(tdatas, 2)
                    textract(lig, k) = tdatas(i, k)
                Next k
            End If
        Else
            n = n + 1
            For k = LBound(tdatas, 2) To UBound(tdatas, 2)
                textract(n, k) = tdatas(i, k)
            Next k
        End If
    End If
Next i

If n > 0 Then
    Sheets.Add(after:=Sheets(1)).Name = "Extract_" & Format(Date, "YYMMDD")
    With Sheets("Extract_" & Format(Date, "YYMMDD"))
        .Rows(1).Value = Sheets(1).Rows(1).Value
        .Cells(2, 1).Resize(n, UBound(textract, 2)) = textract
        '.ListObjects.Add(Source:=.UsedRange, xllistobjecthasheaders:=xlYes).Name = .Name
    End With
End If

End Sub

Function match(vcherchee, tableau As Variant, colonne As Long) As Long
For i = LBound(tableau) To UBound(tableau)
    If tableau(i, colonne) = vcherchee Then
        match = i
        Exit Function
    End If
Next i
End Function

Cdlt,

Bonjour galopin 01. Merci pour vos commentaires. Je l'apprécie beaucoup.

3 Go J'adore la proposition avec PowerVBA.

En regardant le classeur que vous avez présenté. Je me rends compte que j'ai commis une erreur dans mon explication, que je ne suis pas sûr que vous vouliez m'aider à corriger. Mais votre travail est sur la bonne voie.

Il y a 2 choses:

# 1 sur l'onglet de la feuille de calcul "Extract_210123" que vous avez créé. ce sont la seule colonne que je recherche:

Le reste des colonnes dans "Extract_210123" l'onglet peut être supprimé.

#2 Vous avez également fait un excellent travail avec les données fournies. Je n'ai plus besoin du troisième onglet "Feuil1".

Ce sont toutes les informations que je voulais.

Comme je place de nouvelles données sur une base hebdomadaire, sur l'onglet "XLS".

Le résultat souhaité que je recherche est d'obtenir la dernière date avec ses valeurs dans l'onglet "Extraire_210123" uniquement.

Merci à tous pour votre contribution.

Je suis ravi d'avoir bien travaillé .

Je regarderai pour les colonnes.

Il faut savoir que l'onglet "Feuil1" contient la liste des infos à extraire qui est utilisée dans le code. Donc si on supprime cet onglet, il n'y aura plus d'exécution possible. Il est cependant possible de le masquer...

Que voulez-vous faire exactement chaque semaine ? Remplacer les infos ? Ajouter les infos ? Ou créer un nouvel onglet ?

Cdlt,

Merci pour vos commentaires et votre réponse rapide.

# 1 Concernant les données dans l'onglet "XLS". Je vais remplacer les données ... Chaque semaine, de nouvelles données sont ajoutées. Début janvier 2021 à fin décembre 2021.

Donc le plan est. Pour télécharger le dernier fichier. Puis copiez et collez dans l'onglet "XLS". Cliquez ensuite sur le bouton macro et ... Comme par magie. Obtenez les dernières données dans l'onglet "Extract_210123".

Concernant "sheet1", je n'ai aucun problème. Vous n'avez pas besoin de le cacher ...

J'espère que les informations vous aideront.

Merci d'avance

Bonjour,

Non, désolé, je ne comprends toujours pas...

Je me doute que les données de XLS évolueront. Ce n'est pas un problème puisque la macro récupère la dernière opération (date la plus récente) des lignes qui nous intéressent. Mais, dans l'onglet Extract (_210123, c'était pour la date du jour), on peut effacer les données existantes et les remplacer (donc en fait laisser le code tel quel) ou ajouter les nouvelles données exportées à la suite. C'est ça la question !

La feuille "Feuil1" est fondamentale. Dessus, il y a la liste des opérations à extraire. Sans cette liste, le code ne pourra pas deviner ce qu'il doit prendre. C'est pour ça qu'il faut la garder.

Cdlt,

Voici le code mis à jour avec ce qu'il faut changer, à savoir juste le filtre sur les colonnes, et un peu de mise en forme :

Sub test()

Dim textract(), tfiltre(), chaine$

Set reg = CreateObject("vbscript.regexp")
motif = Join(Application.Transpose(Range("Liste")), "|")
tdatas = Sheets(1).UsedRange
ReDim textract(1 To UBound(tdatas), 1 To UBound(tdatas, 2))
reg.Pattern = motif

Call SupprimerExtract ' SUPPRESSION DE LA FEUILLE EXTRACT

'RECUPERATION DES LIGNES (LES + RECENTES) DE LA LISTE "Liste"
For i = LBound(tdatas) To UBound(tdatas)
    chaine = tdatas(i, 1)
    If reg.test(chaine) Or i = 1 Then
        lig = match(chaine, textract, 1)
        If lig > 0 Then
            If tdatas(i, 2) > textract(lig, 2) Then
                For k = LBound(tdatas, 2) To UBound(tdatas, 2)
                    textract(lig, k) = tdatas(i, k)
                Next k
            End If
        Else
            n = n + 1
            For k = LBound(tdatas, 2) To UBound(tdatas, 2)
                textract(n, k) = tdatas(i, k)
            Next k
        End If
    End If
Next i

'SORTIE SI PAS DONNEES
If n < 2 Then
    MsgBox "Désolé... Nous n'avons pas trouvé les données recherchées", vbCritical, "Aucune correspondance"
    Exit Sub
End If

'FILTRE LES COLONNES CIBLEES
ReDim tfiltre(1 To n, 1 To UBound(textract, 2))
motif = Join(Application.Transpose(Range("Titres")), "|")
reg.Pattern = motif

For k = LBound(textract, 2) To UBound(textract, 2)
    chaine = tdatas(1, k)
    If reg.test(chaine) Then
        kk = kk + 1
        For i = 1 To n
            tfiltre(i, kk) = textract(i, k)
        Next i
    End If
Next k

'AJOUT FEUILLE, TABLEAU ET MISE EN FORME
Sheets.Add(after:=Sheets(1)).Name = "Extract"
With Sheets("Extract")
    .Cells(1, 1).Resize(n, kk) = tfiltre
    .ListObjects.Add(Source:=.UsedRange, xllistobjecthasheaders:=xlYes).Name = "Extract" '<<option
    With .Range("Extract")
        .Columns.ColumnWidth = 16
        .Columns(1).ColumnWidth = 60
        With .Rows(0)
            .WrapText = True
            .HorizontalAlignment = xlCenter
            .VerticalAlignment = xlCenter
        End With
    End With
End With

End Sub

Cdlt,

Citation "Je soupçonne que les données XLS vont changer. Ce n'est pas un problème puisque la macro récupère la dernière opération (date la plus récente) à partir des lignes qui nous intéressent. Mais, dans l'onglet Extraire (_210123, c'était pour la date actuelle ), nous pouvons effacer les données existantes et les remplacer (donc en fait laisser le code tel quel) ou ajouter les nouvelles données exportées par la suite ».

C'est la bonne solution.

Le fichier fonctionne parfaitement.

J'aime cela. Merci, merci et merci beaucoup ...

J'apprécie vraiment votre temps et vos efforts donnés ...

https://giphy.com/gifs/clapping-clap-standing-ovation-qIXVd1RoKGqlO/fullscreen