Signature Outlook 2010 automatique à partir d'Excel VBA

Le 20/01/2021 à 12:55

Bonjour,
J'ai lu des tutos mais je ne parviens pas à insérer ma signature enregistrée dans outlook 2010 après la sélection que je colle dans mon mail.
Voici mon bout de code, merci pour votre aide.

Sub EnvoyerParMail()
Dim oOutlook As Object
Set oOutlook = CreateObject("Outlook.Application")

Dim oMail As Object
Set oMail = oOutlook.CreateItem(0)

With oMail

Dim oObjetWord As Object
Set oObjetWord = .GetInspector.WordEditor

.To = "marin.marin@toto.fr"
.CC = "bateau.quinavigue@eau.com
.Subject = "Extraction du flux " & "- " & ThisWorkbook.Name
.Body = ActiveCell.Value
Selection.Copy
oObjetWord.Range(0).Paste

.Display

End With

End Sub
Le 20/01/2021 à 13:21

Bonjour plfiloo

Un code qui j'espère fonctionnera sous 2010 

Sub EnvoyerParMail()
  Dim oOutlook As Object
  Dim oMail As Object
  Dim oObjetWord As Object
  ' Créer une instance d'Outlook
  Set oOutlook = CreateObject("Outlook.Application")
  ' Créer une instance de mail
  Set oMail = oOutlook.CreateItem(0)
  With oMail
    .Display
    .To = "adresse@fai.fr"
    .CC = "adresse@fai.fr"
    .Subject = "Extraction du flux " & "- " & ThisWorkbook.Name
    .HTMLBody = RangetoHTML(Selection) & .HTMLBody
  End With
End Sub

Function RangetoHTML(rng As Range)
' Changed by Ron de Bruin 28-Oct-2006
' Working in Office 2000-2016
    Dim fso As Object
    Dim ts As Object
    Dim TempFile As String
    Dim TempWB As Workbook

    TempFile = Environ$("temp") & "\" & Format(Now, "dd-mm-yy h-mm-ss") & ".htm"

    'Copy the range and create a new workbook to past the data in
    rng.Copy
    Set TempWB = Workbooks.Add(1)
    With TempWB.Sheets(1)
        .Cells(1).PasteSpecial Paste:=8
        .Cells(1).PasteSpecial xlPasteValues, , False, False
        .Cells(1).PasteSpecial xlPasteFormats, , False, False
        .Cells(1).Select
        Application.CutCopyMode = False
        On Error Resume Next
        .DrawingObjects.Visible = True
        .DrawingObjects.Delete
        On Error GoTo 0
    End With

    'Publish the sheet to a htm file
    With TempWB.PublishObjects.Add( _
         SourceType:=xlSourceRange, _
         Filename:=TempFile, _
         Sheet:=TempWB.Sheets(1).Name, _
         Source:=TempWB.Sheets(1).UsedRange.Address, _
         HtmlType:=xlHtmlStatic)
        .Publish (True)
    End With

    'Read all data from the htm file into RangetoHTML
    Set fso = CreateObject("Scripting.FileSystemObject")
    Set ts = fso.GetFile(TempFile).OpenAsTextStream(1, -2)
    RangetoHTML = ts.readall
    ts.Close
    RangetoHTML = Replace(RangetoHTML, "align=center x:publishsource=", _
                          "align=left x:publishsource=")

    'Close TempWB
    TempWB.Close savechanges:=False

    'Delete the htm file we used in this function
    Kill TempFile

    Set ts = Nothing
    Set fso = Nothing
    Set TempWB = Nothing
End Function

@+

Le 20/01/2021 à 14:06

Merci Bruno,

Veuillez excuser le novice que je suis. Je dois copier/coller l'intégralité du code reçu.

Car en le copiant dans un module, je ne visualise pas la signature dans le mail.

Le 20/01/2021 à 14:20

C'est bon cela fonctionne Bruno. super.

Je souhaiterais pour parfaire le travail ajouter du littéral dans le corps du mail avant la copie des cellules...
Du genre : "Bonjour, vous trouverez ci-dessous etc;..."

D'avance merci

Plfiloo.

Le 20/01/2021 à 14:56

Re,

J'ai omis la suppression d'une ligne qui ne sert plus à rien

    Set oObjetWord = .GetInspector.WordEditor

Pour ce qui est du texte,

Sub EnvoyerParMail()
  Dim oOutlook As Object
  Dim oMail As Object
  Dim oObjetWord As Object
  Dim strHTML As String
  ' Créer une instance d'Outlook
  Set oOutlook = CreateObject("Outlook.Application")
  ' Créer une instance de mail
  Set oMail = oOutlook.CreateItem(0)
  With oMail
    .Display
    .To = "adresse@fai.fr"
    .CC = "adresse@fai.fr"
    .Subject = "Extraction du flux " & "- " & ThisWorkbook.Name
    ' Corps
    strHTML = ""
    strHTML = strHTML & "<HEAD>"
    strHTML = strHTML & "<BODY>"
    strHTML = strHTML & "Bonjour,<BR><BR>" _
          & "ma ligne suivante ici,<BR><BR>" _
    & "ma 3ème ligne"
    ' On complète le Body
    .HTMLBody = strHTML & RangetoHTML(Selection) & .HTMLBody
  End With
End Sub

Sinon, tu trouveras d'autres exemples ICI

@+

Rechercher des sujets similaires à "signature outlook 2010 automatique partir vba"