Créer macro débutante

Bonjour,

Je suis ultra nulle pour créer des macros et en fait j’aimerai pour gagner du temps automatiser une action que je dois faire à la main ☹

En fait j’ai plusieurs feuilles de tests qui sont remplis via des documents word et j’ai besoin de consolider chaque feuille de test pour suivi dans excel

Cf word en pièce jointe.

J’aimerai une macro qui me permette de récupérer les informations des différents document word . 1 document = 1 onglet avec le titre 1 pour m'y retrouver

Je suis preneuse de toutes les solutions, je suis désespérée.

Merci de votre aide !

bonjour,

une proposition, mettre la macro dans un fichier excel et lancer la macro via alt-f8

Sub aargh()
    Set appword = CreateObject("word.application") 'ouvrir word
    chemin = "d:\downloads\" 'à adapter répertoire des documents word
    nf = Dir(chemin & "*.docx") 'à adapter filtre pour les fichiers à prendre en compte
    Do While nf <> ""
        nl = 0
        Sheets.Add After:=Sheets(Sheets.Count)
        Set ws = ActiveSheet
        Set doc = appword.documents.Open(chemin & "\" & nf)
        Set tablos = doc.tables
        titre = cl(doc.Paragraphs(1).Range.Text)
        ws.Name = titre
        For i = 1 To tablos.Count
            For k = 1 To tablos(i).Rows.Count
                If (k = 1 And nl = 0) Or k > 1 Then
                    nl = nl + 1
                    For j = 1 To tablos(i).Rows(k).Cells.Count
                        ws.Cells(nl, j) = cl(tablos(i).Rows(k).Cells(j).Range.Text)
                    Next j
                End If
            Next k
        Next i
        doc.Close False
        nf = Dir()
    Loop
    appword.Quit
End Sub
Function cl(t)
    nt = Application.Clean(t)
    cl = Trim(nt)
End Function

Merci ça me convient parfaitement !