Déplacer des lignes dans Excel en fonction de cases non vides

Bonjour à tous,

Je suis à la recherche d'une macro qui me permettrait de déplacer mes lignes lorsqu'une case de cette ligne est remplie. Dans le cas de mon fichier, je souhaite ainsi que si dans mon onglet "Dossiers en cours de traitement", la colonne N "pièces manquantes" est remplie, la ligne bascule automatiquement dans "dossiers en attente" et disparaisse en même temps de l'onglet ""Dossiers en cours de traitement". De la même manière, si une date est renseignée dans mon onglet "Dossiers en cours de traitement" dans la colonne R "Date activation", je souhaiterais que la ligne bascule automatiquement dans "dossiers activés" et disparaisse de ""Dossiers en cours de traitement". J'ai tenté une macro sur un modèle que j'ai trouvé sur ce forum, mais je ne sais pas pourquoi cela ne semble pas fonctionner . Auriez-vous une piste de solution ?

Merci de votre aide et bonne soirée,

Lucile

Salut Lucile,

ainsi, sans doute...

Private Sub Worksheet_Change(ByVal Target As Range)
'
Dim iRow%, iCol%, iOK%
'
If Not Intersect(Target, Union(Columns("N"), Columns("R"))) Is Nothing Then
    Application.EnableEvents = False
    iRow = Target.Row
    iCol = Cells(1, Columns.Count).End(xlToLeft).Column
    If Target.Column = 14 And Target <> "" Then iOK = 1
    If Target.Column = 18 And IsDate(Target) Then iOK = 2
    If iOK > 0 Then
        With Worksheets(IIf(iOK = 1, "Dossiers en attente", "Dossiers activés"))
            .Range("A" & .Range("A" & Rows.Count).End(xlUp).Row + 1).Resize(1, iCol).Value = Range("A" & iRow).Resize(1, iCol).Value
        End With
        Rows(iRow).Delete shift:=xlUp
    End If
    Application.EnableEvents = True
End If
'
End Sub


A+

Bonjour,

C'est exactement ca merci beaucoup !!!!!!

Bonne journée

Rechercher des sujets similaires à "deplacer lignes fonction cases vides"