Ajout de segments sur graphiques (dashboards)

Bonjour le forum,

Je dispose actuellement d'un fichier de consolidation (voir en PJ) composé de 3 onglets:

- "Security measures" : cet onglet constitue ma base de données

- "Calculation" : cet onglet opère des calculs en se basant sur le contenu de "Security measure"

- "Dashboard" : cet onglet exploite les données de l'onglet "Calculation" pour faire apparaitre des graphiques (donuts et spider)

Je souhaiterais mettre en place des segments au niveau de l'onglet "Dashboard" afin de filtrer finement les données qui m'intéresse. Par exemple, au sein de cet onglet, je souhaiterais disposer de filtres afin de faire évoluer les dashboards en fonction de ma sélection. Voici les filtres dont je souhaiterais disposer : je souhaiterais pouvoir sélection/désélectionner selon mon besoin les données présentes au sein de la colonne BU, de la colonne Région, de la colonne Entity, de la colonne RW et de la colonne Priority (ces colonnes sont présentes au sein de "Security measures").

Avez-vous une idée de comment je pourrais m'y prendre pour pouvoir opérer finement ce type filtre sur mes graphiques ?

Merci d'avance à ceux qui se pencheront sur le sujet !

Bonne journée à tous,

Thomas

Bonjour

Sauf erreur de ma part tous les calcul sont issus de l'onglet CALCULATION à base de SOMME.SI et NB.SI qui ne tiennent pas compte de filtres sur la plage

Donc il faut ajouter une colonne dans la source, nommée par exemple Filtre, avec une formule du type =SOUS.TOTAL(103;[@BU])

et adapter les formule pour prendre en compte cette colonne

=NB.SI.ENS(GLOBAL_DATA[Security pack];[@PACKFORMULA];GLOBAL_DATA[Priority];">=P2";GLOBAL_DATA[Status];Status_No_Project;GLOBAL_DATA[filtre];1)

Bonjour 78chris,

Oui c'est ce qui bloque actuellement tout le processus.

Pourriez-vous me donner un exemple au sein du fichier ? Je ne vois pas très bien où est ce que vous ajouteriez cette colonne.

Merci d'avance,

RE

en première ou dernière colonne du tableau de l'onglet SECURITY MEASURES sur lequel vont porter les segments

Bonjour,

J'ai suivi vos conseils en ajoutant des colonnes filtre au sein de l'onglet SECURITY MEASURES (colonnes AW, AX,...) et adapté les formules de 2 colonnes (F et G) au sein de l'onglet CALCULTATION mais cela ne semble pas fonctionner. Les formules modifiées dans l'onglet CALCULATION ne ressortent que des résultats égal à 0.

Merci d'avance pour votre aide,

J'ai également réussi à ajouter des segments au sein de l'onglet DASHBOARD. Je pense que cela sera plus simple pour filtrer les données directement depuis mes DASHBOARD.

Pour ce qu'il s'agit des formules à adapter au sein de l'onglet CALCULRATION, j'ai vu sur certains forum que la formule "SOMMEPROD" était souvent utilisée. Je ne vois pas très comment cette formule fonctionne, pensez-vous que celle-ci est compatible avec ma recherche ?

Bonjour

Tu n'a pas compris la fonction SOUS.TOTAL une seule colonne suffit mais il faut utiliser

SOUS.TOTAL(103;[@BU])

Quel que soit le filtre si la ligne est masqué cela affiche 0 et sinon 1, peu importe le filtre qui l'a masquée et donc un seul critère à ajouter dans les formules de CALCULATION
(là tu as des valeurs qui ne sont pas 1 donc ta formule renvoie 0)

Pas besoin de SOMMEPROD ici

Re-bonjour,

Pour que mes Dashboards fonctionnent il est nécessaire d'avoir des valeurs au sein de mon onglet CALCULATION. Or, lorsque j'adapte mes formules comme indiqué plus haut, je tombe quoi qu'il arrive sur un total de 0. Je comprends pas pourquoi j'obtient un chiffre nul alors que je suis sensé obtenir de nombreux chiffres, même avec les filtres mis en place.

RE

Si elle est correcte tu vois 1 dans cette colonne et si les formules de CALCULATION utilisent bien cette colonne avec comme critère 1 cela fonctionne

Il faut donc mettre à jour toutes les formules de E à BY à quelques exceptions près

Bonjour

=SIERREUR(ARRONDI(SOMME.SI.ENS(GLOBAL_DATA[Target scope];GLOBAL_DATA[Security pack];[@PACKFORMULA];GLOBAL_DATA[filtre];1)/[@[IN SCOPE]];4);0)

=SIERREUR(ARRONDI(SOMME.SI.ENS(GLOBAL_DATA[Global Progress rate];GLOBAL_DATA[Security pack];[@PACKFORMULA];GLOBAL_DATA[Status];DATA!$J$6;GLOBAL_DATA[filtre];1)/[@[IN SCOPE]];4);0)

=SI((SIERREUR(ARRONDI(SOMME.SI.ENS(GLOBAL_DATA[Global Progress rate];GLOBAL_DATA[Security pack];[@PACKFORMULA];GLOBAL_DATA[Impl_Yes];1;GLOBAL_DATA[filtre];1)/[@[IN SCOPE]];4);0)-[@[CURRENT IMPL DONE ]])<0;0;(SIERREUR(ARRONDI(SOMME.SI.ENS(GLOBAL_DATA[Global Progress rate];GLOBAL_DATA[Security pack];[@PACKFORMULA];GLOBAL_DATA[Impl_Yes];1;GLOBAL_DATA[filtre];1)/[@[IN SCOPE]];4);0)-[@[CURRENT IMPL DONE ]]))

=SIERREUR(ARRONDI(SOMME.SI.ENS(GLOBAL_DATA[Global Progress rate];GLOBAL_DATA[Security pack];[@PACKFORMULA];GLOBAL_DATA[filtre];1)/[@[IN SCOPE]];4);0)

Bonjour,

Une énorme merci !!