Trier avec une double Référence

Bonjour,

Je débute dans le langage "VBA", j'aimerai faire une gestion de stock, sauf que j'ai 2 référence.

Exemple : Dans NE01 il y a la réf 1"123" j'aimerai donc ajouté toute les doublons de cette réf soit effacé afin d'etre remplacé avec la quantité voulu.

(Exemple en Image pour le résultat final [sachant que mon but final est de remplacer directement les lignes et ne pas mettre un tableau sur le coté])

Merci

Bonjour,

j'ai une soluce

Sub Regroupe()

Dim cell As Range
Dim sRef1 As String
Dim sRef2 As String
Dim iQte As Integer

'tri par colonne A puis colonne B
    With ActiveSheet.Sort
        .SortFields.Clear
        .SortFields.Add Key:=Range("A2:A" & Range("A2").CurrentRegion.Rows.Count), _
            SortOn:=xlSortOnValues, Order:=xlAscending, DataOption:=xlSortNormal
        .SortFields.Add Key:=Range("B2:B" & Range("A2").CurrentRegion.Rows.Count), _
            SortOn:=xlSortOnValues, Order:=xlAscending, DataOption:=xlSortNormal
        .SetRange Range("A1:C" & Range("A2").CurrentRegion.Rows.Count)
        .Header = xlYes
        .Apply
    End With

    For Each cell In Range("A2:A" & Range("A2").CurrentRegion.Rows.Count)
        If cell.Value = sRef1 Then 'cas ref1 identique
            If cell.Offset(0, 1).Value = sRef2 Then
                iQte = iQte + cell.Offset(0, 2).Value
                cell.Offset(0, 2).Value = iQte
            Else
                sRef2 = cell.Offset(0, 1).Value
                iQte = cell.Offset(0, 2).Value
            End If
        Else 'cas ref1 différent
            sRef1 = cell.Value
            sRef2 = cell.Offset(0, 1).Value
            iQte = cell.Offset(0, 2).Value
        End If
        If cell.Offset(1, 0).Value = sRef1 And cell.Offset(1, 1).Value = sRef2 Then cell.EntireRow.ClearContents
    Next

    'tri par colonne A puis colonne B
    With ActiveSheet.Sort
        .SortFields.Clear
        .SortFields.Add Key:=Range("A2:A" & Range("A2").CurrentRegion.Rows.Count), _
            SortOn:=xlSortOnValues, Order:=xlAscending, DataOption:=xlSortNormal
        .SortFields.Add Key:=Range("B2:B" & Range("A2").CurrentRegion.Rows.Count), _
            SortOn:=xlSortOnValues, Order:=xlAscending, DataOption:=xlSortNormal
        .SetRange Range("A1:C" & Range("A2").CurrentRegion.Rows.Count)
        .Header = xlYes
        .Apply
    End With

End Sub

je joins le fichier qui fonctionne

à voir pour une adaptation de ce code.

:)

Bonjour, désolé pour le temps de réponse. C'est bon j'ai réussi à l'adapter à mon programme. Merci beaucoup!