Supprimer lignes vides

Salut chers Tous

je voudrais par macro supprimer toutes les lignes vides comprises entre la ligne 6 et la ligne contenant le mot "REF" de ma colonne A.

J"ai élaboré ce code mais apparemment quelques détails m’échappent. Mon Code supprime les lignes vides au dessus de la ligne 6. Aidez moi à corriger.

Sub SupprimerLignesVide()
Dim MaPlage As Range
Dim iCompteur As Long
Dim x As Variant, dl As Long
dl = Range("A" & Rows.Count).End(xlUp).Row
x = Application.Match("REF", Range("A6:A" & dl), 0)
Set MaPlage = ActiveSheet.Range("A6:A" & x)
For iCompteur = MaPlage.Rows.Count To 1 Step -1
If Application.CountA(Rows(iCompteur).EntireRow) = 0 Then
Rows(iCompteur).Delete
End If
Next iCompteur
End Sub

Bonsoir,

une proposition de code :

Sub Test()
    Dim Trouve As Range, I
    Set Trouve = Range("A:A").Find("Ref", lookat:=xlWhole)
    If Not Trouve Is Nothing Then
        For I = Trouve.Row To 7 Step -1
            If WorksheetFunction.CountIf(Range("A" & I & ":F" & I), "><") = 0 Then
                Range("A" & I).EntireRow.Delete
            End If
        Next I
    End If
End Sub

On cherche "Ref" avec FIND, on met dans Trouve le RANGE du résultat de la recherche, on boucle de la ligne du Trouve à 7 avec un décompte de -1, si on compte 0 valeurs quelconque sur la ligne testée du tableau alors on efface.

@ bientôt

LouReeD

Bonjour à toutes et tous,

Une autre proposition.

Sub SupprimerLignesVide()
Dim Compteur As Long, x As Variant
    Application.ScreenUpdating = False
    With ActiveSheet
        On Error Resume Next
        x = Application.Match("REF", .Columns(1), 0)
        If Not IsError(x) Then
            For Compteur = x To 6 Step -1
                If Application.CountA(.Rows(Compteur).EntireRow) = 0 Then
                    .Rows(Compteur).Delete
                End If
            Next Compteur
        End If
    End With
End Sub

Merci beaucoup

Merci pour votre retour et remerciement !

@ bientôt

LouReeD