Fonction SI (ET & OU imbriqués)

Bonjour le forum,

Je cherche à affiner la fonction suivante :

=SI(ET([@[Implementation progress rate]]<100%;[@[Re-estimated end]]<=SYNTHESIS!ReportingDate;[@[Re-estimated end]]<>"");1;0)+SI(ET([@[Implementation progress rate]]<100%;[@[Initial end]]<=SYNTHESIS!ReportingDate;[@[Initial end]]<>"");1;0)+SI(ET(OU([@[Target scope]]=Target_Not_Applicable;[@[Target scope]]=Risk_accepted);[@[Kick-off]]<>"");1;0)+SI(ET([@Status]="IN PROGRESS";[@[Implementation progress rate]]="0%");1;0)

Le passage en orange me pose un problème. Actuellement ma formule en orange recherche les cas où mon Implementation progress rate est < à 100% ET où mon Initial end date est <= à ma Reporting Date ET où mon Initial end n'est pas vide. Si c'est le cas ma fonction affiche 1, si ce n'est pas le cas ma fonction affiche 0.

Je souhaiterais que ma fonction recherche seulement les cas où mon Implementation progress rate <100% ET (mon Initial end date <= à ma Reporting Date OU mon Re-estimated date (qui est une autre cellule) <= Reporting Date)

Pour ce faire j'ai tenté d'imbriquer une fonction SI(ET(OU mais je rencontre un problème de parenthèse...

Merci à vous !

Bonjour,

Est-ce cela que vous voulez ?

=SI(
    ET( [@[Implementation progress rate]]<1 ; [@[Re-estimated end]]<=SYNTHESIS!ReportingDate ; [@[Re-estimated end]]<>"")
;1;0)

+ SI(
    ET( [@[Implementation progress rate]]<100%;
        OU( [@[Initial end]]<=SYNTHESIS!ReportingDate ; [@[Initial end]]<>"")
    )
;1;0)

+SI(
    ET([@[Kick-off]]<>"";
        OU( [@[Target scope]]=Target_Not_Applicable ; [@[Target scope]]=Risk_accepted )
    )
;1;0)

+SI(
    ET([@Status]="IN PROGRESS";[@[Implementation progress rate]]="0%")
;1;0)

Cordialement,

Formule qui équivaut à :

= ET( [@[Implementation progress rate]]<1 ; [@[Re-estimated end]]<=SYNTHESIS!ReportingDate ; [@[Re-estimated end]]<>"")

+ ET( [@[Implementation progress rate]]<1; OU( [@[Initial end]]<=SYNTHESIS!ReportingDate ; [@[Initial end]]<>""))

+ ET([@[Kick-off]]<>""; OU( [@[Target scope]]=Target_Not_Applicable ; [@[Target scope]]=Risk_accepted ))

+ ET([@Status]="IN PROGRESS";[@[Implementation progress rate]]="0%")

Bonjour,

Ce que je souhaiterais c'est d'inclure ou condition "OU" à l'intérieur de la fonction actuelle afin de recherche seulement les cas où mon Implementation progress rate <100% ET (mon Initial end date <= à ma Reporting Date OU mon Re-estimated date (qui est une autre cellule) <= Reporting Date)

Actuellement ma fonction affiche "1" alors même qu'une Re-estimated date est précisée. Si mon Initial end date est <= Reporting et qu'une Re-estimated date a été précisée et qu'elle est > à Reporting Date alors je voudrais afficher "0"

J'espère que j'ai été plus clair

Bonjour,

D'accord, je comprends mieux. Je crois qu'il faut faire comme ça :

= ET( [@[Implementation progress rate]]<1 ; 
        OU(
            ET([@[Re-estimated end]]<=SYNTHESIS!ReportingDate ; [@[Re-estimated end]]<>"");
            ET([@[Initial end]]<=SYNTHESIS!ReportingDate ; [@[Initial end]]<>"")
        )
  )

+ ET([@[Kick-off]]<>""; OU( [@[Target scope]]=Target_Not_Applicable ; [@[Target scope]]=Risk_accepted ))

+ ET([@Status]="IN PROGRESS";[@[Implementation progress rate]]="0%")

Cdlt,