Macro pour envoyer un PDF issue d un fichier Excel

ok merci je te l envoie de suite

Donc reprenons

remplacer :

With destwb
.ExportAsFixedFormat Type:=xlTypePDF, Filename:=TempFilePath & TempFileName & ".pdf", Quality:=xlQualityStandard, _
IncludeDocProperties:=True, IgnorePrintAreas:=False, OpenAfterPublish:=False ' sauvegarde du fichier au format pdf

par :

With destwb
With .ActiveSheet.PageSetup
    .Orientation = xlLandscape
     .Zoom = False
     .FitToPagesTall = 1
     .FitToPagesWide = 1
End With
.ExportAsFixedFormat Type:=xlTypePDF, Filename:=TempFilePath & TempFileName & ".pdf", Quality:=xlQualityStandard, _
IncludeDocProperties:=True, IgnorePrintAreas:=False, OpenAfterPublish:=False ' sauvegarde du fichier au format pdf

Fred

Ça ne marche pas fred,

le document s'edite bien en PDF mais avec toutes les colonnes comme avant

Cdlt

donne un fichier pdf que tu fais a la main du resultat que tu voudrais !

car là je ne vois pas ce que tu attends

fred

JE T envoie en MP

Merci

rajoute cette ligne

    .PrintArea = "$A$1:$K$" & [A65536].End(xlUp).Row

dans

With .ActiveSheet.PageSetup
    .PrintArea = "$A$1:$K$" & [A65536].End(xlUp).Row
    .Orientation = xlLandscape
     .Zoom = False
     .FitToPagesTall = 1
     .FitToPagesWide = 1
End With

fred

Impécable ca fonctionne

Merciiiiiiiiiiiiii Fred

Bonjour,

Je suis très novice sur les Macro. Ce code fonctionne très bien. En effectuant la macro, le mail est envoyé .

Néanmoins j'aurais besoin que le mail ne soit pas envoyé, qu'il s'affiche en tant que "nouveau courrier" avec la pièce jointe. Qu'est-ce qu'il faut modifier dans ce code ?

Merci beaucoup,

fred2406 a écrit :

bonjour et bienvenu

voici un code que j'ai en stock qui fait ce que tu demande

a adapter au niveau des destinataires /sujet/corps du texte du mail a envoyer

fred

Sub mail()
'Fonctionne sous excel 2000-2013
Dim FileExtStr As String
Dim FileFormatNum As Long
Dim Sourcewb As Workbook
Dim destwb As Workbook
Dim TempFilePath As String
Dim TempFileName As String
Dim OutApp As Object
Dim OutMail As Object
Dim S As Shape

With Application
    .ScreenUpdating = False
    .EnableEvents = False
End With

Set Sourcewb = ActiveWorkbook

'Copie la feuille active comme nouvelle feuille

ActiveSheet.Copy
Set destwb = ActiveWorkbook

'Désactiver fenêtre de compatibilité
        Application.DisplayAlerts = False
'----------------------------------------------------------------------------
'Sauvegarde la nouvelle feuille/L'envoie par mail/La supprime
'----------------------------------------------------------------------------

TempFilePath = Environ$("temp") & "\"
TempFileName = ActiveSheet.Name

Set OutApp = CreateObject("outlook.application")
Set OutMail = OutApp.CreateItem(0)

With destwb
.ExportAsFixedFormat Type:=xlTypePDF, Filename:=TempFilePath & TempFileName & ".pdf", Quality:=xlQualityStandard, _
IncludeDocProperties:=True, IgnorePrintAreas:=False, OpenAfterPublish:=False        ' sauvegarde du fichier au format pdf

    On Error Resume Next
    With OutMail
        .To = "fred@toto.fr"
        .CC = "Moi@toto.fr"
        .bcc = ""
        .Subject = "sujet du mail"
        .Attachments.Add TempFilePath & TempFileName & ".pdf"
        .Body = "Bonjour, le message a mettre dans le mail "
        '.display 'ou alors utiliser
        .Send 'pour envoi
    End With
    On Error GoTo 0
    .Close savechanges:=False
End With

    'Effacer le fichier envoyé
Kill TempFilePath & TempFileName & ".pdf"

Set OutMail = Nothing
Set OutApp = Nothing

With Application
    .ScreenUpdating = True
    .EnableEvents = True
    End With

End Sub

EDIT : je viens de modifier pour faire l'enregistrement au format pdf qui n'étais pas fait (c'était au format excel la piece jointe)

Bonjour Fred,

Pour reprendre ce code. j'aurais besoin que le mail ne soit pas envoyé, qu'il s'affiche en tant que "nouveau courrier" avec la pièce jointe sans être envoyé. Qu'est-ce qu'il faut modifier dans ce code ?

Bonsoir

pour préparer le mail sans l'envoyer

rendre actif cette ligne

.display 

et mettre en commentaire celle ci

 '.Send 'pour envoi

fred

je déterre le topic,

mais pourrait-on me dire quoi supprimé dans la macro pour enlever la copie du classeur svp

Bonsoir Tonytct..

Merci d'ouvrir un sujet en expliquant ce que tu recherches à faire.. tu peux donner ce cas ou le lien vers ce post.

Fred