With Sheets Non pris en compte

Bonjour,

j'ai ici une code simple qui crée des bordures en diago.

Cependant il est supposé fonctionner seulement sur ma feuille ("FICHE CONDITIONNEMENT PRODUIT")

Or ce n'est pas le cas, c'est la feuille active qui prends les motifs.

Il y a sans doute une truc avec With que je ne maîtrise pas .

Merci pour votre aide !

Sub Bordure()

    With Sheets("FICHE CONDITIONNEMENT PRODUIT")
        With Range("A5,B6,C7,D8,E9:F10").Borders(xlDiagonalDown)
                .LineStyle = xlContinuous
                .ColorIndex = 0
                .TintAndShade = 0
                .Weight = xlMedium
            End With
        End With

        With Sheets("FICHE CONDITIONNEMENT PRODUIT")
        With Range("A10,B9,C8,D7,E6,F5").Borders(xlDiagonalUp)
                .LineStyle = xlContinuous
                .ColorIndex = xlAutomatic
                .TintAndShade = 0
                .Weight = xlMedium
            End With
        End With

   End Sub

Bonjour,

Essaie ainsi :

Sub Bordures()
    With Sheets("FICHE CONDITIONNEMENT PRODUIT")
        With .Range("A5,B6,C7,D8,E9:F10").Borders(xlDiagonalDown)
            .LineStyle = xlContinuous
            .ColorIndex = 0
            .TintAndShade = 0
            .Weight = xlMedium
        End With
        With .Range("A10,B9,C8,D7,E6,F5").Borders(xlDiagonalUp)
            .LineStyle = xlContinuous
            .ColorIndex = xlAutomatic
            .TintAndShade = 0
            .Weight = xlMedium
        End With
    End With
End Sub

Merci ça semble fonctionner.

Mon erreur étai dans le "."range ?

Dans quel condition il faut mettre un point après un with ".........."

Bonjour, salut Jean-Eric !

Cobzy a écrit :

Dans quel condition il faut mettre un point après un with ".........."

Tout le temps ! Sinon ton with ne sert à rien...

Le principe :

UnObjet.Value = "Bonjour"
UnObjet.Interior.ColorIndex = xlNone
UnObjet.Formula = "=TRUC()"

With t'évites de répéter inutilement UnObjet, mais pour comprendre que ça s'y rattache, il faut garder le . qui sépare UnObjet de sa propriété. On obtient donc :

With UnObjet
    .Value = "Bonjour"
    .Interior.ColorIndex = xlNone
    .Formula = "=TRUC()"
End With

PS : tu peux tout de même faire référence à un autre objet dans une structure With :

With UnObjet
    .Value = "Bonjour"
    .Interior.ColorIndex = xlNone
    .Formula = "=TRUC()"
    UnAutreObjet.Value = "Aurevoir"
End With

Enfin, comme le montre le code de Jean-Eric, tu peux imbriquer plusieurs structures With les unes dans les autres.