RechercheV avec 2 valeur fixe
Bonjour,
Je bloque sur une construction de formule (je suis novice en la matière).
Je cherche à lancer une recherche avec condition en fonction de 2 valeur saisie manuellement.
Dabord, en fonction d'une valeur en Cellule D, la recherche se fera sur l'un des 2 onglets de "listing".
Ensuite, recherche la valeur de la Cellule A dans l'un de "Listing" pour compléter la cellule B.
Ma formule fonctionnais très bien avant de vouloir crée de "Listing" différent et donc pas besoin d'une phase 1.
Le but étant de faire un planning avec des valeurs non modifiable accidentellement vu que certaine information servent sur d'autres feuilles de calcule.
Voici la formule en question :
=SIERREUR(SI(D31="ETT");SI(RECHERCHEV(A31;'Listing&Suivi ETT '!A:E;2;FAUX)="";"";RECHERCHEV(A31;'Listing&Suivi ETT '!A:E;2;FAUX));SI(D31="CDI");SI(RECHERCHEV(A31;'Listing CDI '!A:E;2;FAUX)="";"";RECHERCHEV(A31;'Listing CDI '!A:E;2;FAUX));"")
Voici la 1er sans condition de la cellule D :
=SIERREUR(SI(RECHERCHEV(A31;'Listing CDI '!A:E;2;FAUX)="";"";RECHERCHEV(A31;'Listing CDI '!A:E;2;FAUX));"")
Par avance merci pour votre aide précieuse.
Bonjour Mattc et bienvenue sur le forum,
Si tu veux augmenter les chances de recevoir des réponses il est important de respecter certaines règles.
Prends deux minutes pour lire ces conseils https://forum.excel-pratique.com/viewtopic.php?f=2&t=13
Cordialement
Bonjour ddetp88,
Merci pour l'accueil.
J'ais pris le temps de lire les conseils.
Par contre je sais pas si j'ai fait une erreur sur mon post ...si il y a une, je veut bien un éclaircissement étant nouveau sur ce forum.
J'ai vus qu'il était mieux d'y joindre le fichier pour facilité l'aide mais il y a beaucoup d'informations confidentiel professionnelle.
Bonsoir.
Envoie-nous le fichier Excel lui-même. Nous pourrons sans doute mieux t'aider.
re,
Effectivement un fichier permet de tester la réponse proposée.
Tu n'as pas la possibilité de l'anonymer ou de créer un exemple montrant le problème?
A voir, tes formules semblent respecter l'écriture attendue.
Merci
en relisant ta formule, tu dois avoir des parenthèses mal placées.
Si( test; condition vraie; si( etc..
Re,
j'ai essayé de l’anonymiser au max.
Le but est que, en fonction du contrat (CDI ou ETT) les information soit rechercher sur une liste différente.
Je me suis dit la même chose sur les parenthèse et me suis penché dessus plusieurs heures sans trouver l'erreur mais, en même temps, je suis novice sur excel.
Bonjour,
Je ne retrouve pas trace de ta formule.
Prends l'habitude de renseigner où se situe le problème dans ton fichier. Ceux qui t'aident apprécieront.
Peux-tu me donner la ou les cellules concernées?
Par ailleurs, tu as des listes de validation de données qui cohabitent avec des formules. La cohabitation n'est pas bonne. Dès que tu saisiras une données à l'aide de la liste, la formule disparaitra. Il faut choisir ou l'une ou l'autre.
Merci
Je pense avoir trouvé les cellules concernées,
en D22 :
=SIERREUR(SI(ESTNA(EQUIV($A22;'Listing CDI '!$A:$A;0)>0);RECHERCHEV($A22;'Listing&Suivi ETT'!$A:$E;4;0);RECHERCHEV($A22;'Listing CDI '!$A:$E;4;0));"")A adapter car pas de ETT en feuille Listing&SuiviETT
Cdt
Bonjour ddetp88,
Merci pour tes réponses et ton aide.
Pour mieux expliquer, voici l'objectif du tableau et surtout des cellules A à E :
- la A est une liste déroulante pour sélectionner le Nom.
- la D est également une liste déroulante pour sélectionner le type de contrat.
- les cellule B et C devront faire une recherche, d’abord par le type de contrat indiqué en D (savoir dans quelles liste/onglet continuer) puis prendre référence du nom de la cellule A pour faire la recherche et compléter les information (à savoir prénom et matricule voir même plus tard la cellule F ...je réfléchi encore).
Du coup j'ai essayer ces deux formules sans grand succès hélas :
1 -] =SIERREUR(SI(D10="ETT";RECHERCHEV(A10;'Listing&Suivi Interim '!A:E;2;FAUX)="";"";RECHERCHEV(A10;'Listing&Suivi Interim '!A:E;2;FAUX));SI(D10="CDI";RECHERCHEV(A10;'Listing CDI'!A:E;2;FAUX)="";"";RECHERCHEV(A10;'Listing CDI'!A:E;2;FAUX));"")
2 -] =SIERREUR(SI(D10="ETT");SI(RECHERCHEV(A10;'Listing&Suivi Interim '!A:E;2;FAUX)="";"";RECHERCHEV(A10;'Listing&Suivi Interim '!A:E;2;FAUX));SI(D10="CDI");SI(RECHERCHEV(A10;'Listing CDI '!A:E;2;FAUX)="";"";RECHERCHEV(A10;'Listing CDI '!A:E;2;FAUX));""
Le but d'avoir 2 listes séparées est de pouvoir faire, par la même occasion, un suivi des ETT (intérimaires) sur les périodes, les FM, des commentaires ..etc.
J'ai essayé la formule que tu m'a envoyé et elle à l'air de bien fonctionner.
Je vais tester plus tard dans la journée sur le tableau avec les vrais informations.
Merci beaucoup pour ton aide.
Essaie cette formule ne B2
=SIERREUR(SI($D10="ETT";RECHERCHEV($A10;'Listing&Suivi ETT'!$A:$E;4;0);SI($D10="CDI";RECHERCHEV($A10;'Listing CDI '!$A:$E;2;0);""));"")et celle-ci en C2
=SIERREUR(SI($D10="ETT";RECHERCHEV($A10;'Listing&Suivi ETT'!$A:$E;4;0);SI($D10="CDI";RECHERCHEV($A10;'Listing CDI '!$A:$E;2;0);""));"")Cdt
Re,
Vraiment parfait, rien à dire. Merci énormément pour ton aide.
J'ai juste modifié la formule sur "RECHERCHEV" pour selectionner la bonne colonne à savoir :
- pour la cellule B = colonne 2
- pour cellule C = colone 3
Ce qui donne :
Cellule B =SIERREUR(SI($D10="ETT";RECHERCHEV($A10;'Listing&Suivi ETT'!$A:$E;2;0);SI($D10="CDI";RECHERCHEV($A10;'Listing CDI '!$A:$E;2;0);""));"")
Cellule C =SIERREUR(SI($D10="ETT";RECHERCHEV($A10;'Listing&Suivi ETT'!$A:$E;3;0);SI($D10="CDI";RECHERCHEV($A10;'Listing CDI '!$A:$E;3;0);""));"")
Je peux clôturer ce post et déclarer mon problème "Résolu".
Encore merci.