Macro "boucle for" répétitive: je galère
Bonjour,
J'ai un tableau excell de plus de 5000 lignes.
Dans la colonne A, j'ai un n° de référence article, qui commencent en A2 jusque A5015.
Dans les colonnes B à K, j'ai des caractéristiques de mon article. (soit 10 caractéristques)
Je souhaite créer une macro qui a pour but de :
reprendre chaque n° d'article (A2) , et le recopier 10 fois dans la colonne A d'une autre feuille (sheet2). Ensuite, passer à l'article suivant (A3) et le recopier 10 fois sous les 10 premiers, et ainsi de suite jusqu'à l'article 5015. J'aurai donc 50150 lignes.
Ensuite, copier les valeurs de chaque colonnes caractéristqiues de mon article A2, et les coller en transposition dans la colonne B de l'autre feuille (sheet2)... et répéter cette action pour les 5015 lignes de 10 valeurs.
Comme résultat, j'obtiendrai donc un tableau de 50150 lignes sur 2 colonnes:
pour chaque ligne : colonne A = une n° d'article, et colonne B une caractéristique de cet article.
Qui pourrait m'expliquer ou m'aider à le faire?
Merci beaucoup
bonjour,
Voici une 'tite macro qui te fera ça très bien :
Sub galopin()
Dim iLR1&, WsS As Worksheet, WsC As Worksheet, Tablo
'Gèle l'écran pour accélérer le traitement
Application.ScreenUpdating = False
'On travaille sur une instance pour accélérer le traitement
Set WsS = Worksheets("Feuil1") 'Feuille Source
Set WsC = Worksheets("Feuil2") 'Feuille Cible
'Détermination de la dernière ligne
iLR1 = WsS.Cells(65535, 1).End(xlUp).Row
'Charge en mémoire les valeurs de
Tablo = WsS.Range("A2:K" & iLR1)
'Pour chaque ligne dans Tablo
For i = 1 To UBound(Tablo)
For k = 1 To 10
'On remplit la feuille cible
WsC.Cells((10 * i) - 9 + k, 1) = Tablo(i, 1)
WsC.Cells((10 * i) - 9 + k, 2) = Tablo(i, k + 1)
Next
Next
Application.ScreenUpdating = True
End SubYa juste à remplacer le nom des feuilles Source et feuille Cible (Lignes 6 et 7)
A+
WAAAAAAW merci beaucoup, et merci pour les détails commentaires, car cela m'aide à comprendre mes erreurs.
C'est tip top ce que je cherchais depuis ce matin... Merci!!