Masquer colonne 1 sur 2

bonjour,

j'ai besoin de masquer ou d'afficher une colonne sur deux a partir de la colonne "D" et jusqu' a "cz".

macro fonctionne bien jusqu 'à "AQ".

quelle serait la solution?

merci de votre aide

bonne journée

cordialement

ma macro

Sub Masquer_Colonnes()

Sheets("recapitulatif").Range("L:l,n:n,p:p,r:r,T:T,V:V,x:x,z:z,ab:ab,ad:ad,af:af,ah:ah,aj:aj,al:al,an:an,ap:ap,aq:aq").EntireColumn.Hidden = True

End Sub

Sub Afficher_Colonnes()

Sheets("recapitulatif").Range("L:aq").EntireColumn.Hidden = False

End Sub

Bonjour,

Par exemple :

Option Explicit
Sub Masquer_Colonnes()
Const a$ = "L"
Const z$ = "CZ"
Dim i As Integer
  Application.ScreenUpdating = False
  For i = Columns(a).Column To Columns(z).Column Step 2
    Worksheets("recapitulatif").Columns(i).Hidden = True
  Next i
End Sub
Sub Afficher_Colonnes()
  Worksheets("recapitulatif").Columns.Hidden = False
End Sub

Ou plus rapide :

Sub Masquer_Colonnes()
Const a$ = "L"
Const z$ = "CZ"
Dim r As Range
Dim i As Integer
  Set r = Worksheets("recapitulatif").Columns(a)
  For i = Columns(a).Column + 2 To Columns(z).Column Step 2
    Set r = Union(r, Worksheets("recapitulatif").Columns(i))
  Next i
  r.EntireColumn.Hidden = True
End Sub
Sub Afficher_Colonnes()
  Worksheets("recapitulatif").Columns.Hidden = False
End Sub

bonjour Patrice

merci à toi pour ton savoir, et ta rapidité.

bonne journée

bien cordialement

Jean Pierre