Copie vers une destination variable

Bonjour,

Je souhaite copier une plage définie dans une feuille d'un fichier (feuille2), vers une autre feuille du fichier (feuille1) mais avec une destination qui doit être une cellule variable.

Ci joint macro avec une destination fixe définie (a5 en l'occurence)

Sub Macro3()

'

' Macro3 Macro

'

'

Sheets("Feuil2").Select

Selection.Copy

Sheets("Feuil1").Select

Range("A5").Select

ActiveSheet.Paste

End Sub

Comment modifier la macro pour définir à chaque manipulation, la destination ?

Merci pour votre réponse

Bonjour Bernard, bonjour le forum,

Comment veux-tu que l'on te réponde si tu n es pas foutu de nous fournir plus de détails !?... Ça ne veut rien dire une destination variable.

La règle d'or en VBA c'est d'éviter autant que tu les peux les Select inutiles qui ne font que ralentir l'exécution du code et sont source de nombreux plantage.

Une esquisse de code où manquent les infos que tu n'as pas fournies :

Sub Macro1()
Dim PL As Range
Dim DEST As Range

Set PL = Sheets("Feuil2").Range(ta_plage) ?
Set DEST='si tu daignais nous en dire plus...
PL.Copy DEST
End Sub

Mes excuses pour le manque de clarté.

Lorsque la macro se déroule après la copie de la plage prédéfinie, je souhaite que l'exécution soit stoppée pour que je puisse définir une cellule de destination, et qu'ensuite la macro redémarre pour faire le "coller".

Exemple d'utilisation:

La plage est est constituée par 4 lignes réparties sur 8 colonnes et représente un modèle d'écriture comptable .

Cette plage est appelée à être copiée tous les mois, dans une feuille de saisie, mais à des emplacements différents.

Re,

Le code :

Sub Macro1()
Dim PL As Range 'déclare la variable PL (PLage)
Dim DEST As Range 'déclare la variable DEST (cellule de DESTination)

Set PL = Selection 'définit la plage PL
'définit la cellule de destination DEST
On Error Resume Next 'gestion des erreurs (en cas d'érreur passe à la ligne suivante)
Set DEST = Application.InputBox("Cliquer sur l'onglet de destination puis, dans la cellule destination.", "DESTINATION", Type:=8)
If Err <> 0 Then Exit Sub 'permet l'utilisation du bouton [Annuler] dans la boîte d'entrée
PL.Copy DEST 'copie la plage PL et la colle dans DEST
Application.Goto DEST 'va à la cellule DEST
End Sub

La procédure :

1. Sélectionne la plage à copier

2. Lance la macro

3. Clique sur l'onglet destination

4. Clique dans la cellule destination

5. Valide avec OK...