Déduction temps de pause

bonjour,

j'ai besoin de trouver une formule qui me permet de déduire un temps de pause de 30 min si le nombre total d'heures de travail est supérieur ou égal à 6h de travail et ne pas les déduire si inférieur à 6h de travail.

Ce sont des heures variables, c'est à dire que il peut y avoir des heures de nuit.

de plus, je voudrais une seule formule dans une seule cellule C1 c'est à dire :

début travail A1 fin de travail B1 total heures de travail C1

A1=8 B1=16 C1=8-0,5 ou A1=22 B1=6 C1=8-0,5 pause car 8>6h de travail

et je veux donc que la déduction ne s'effectue pas si

A1=8 B1=12 C1=4 ou A1=22 B1=2 C1=4 donc pas de pause car 4h<6h de travail

j'espère avoir été assez clair

merci

bonjour maqueval,

Si les horaires sont au format nombre utiliser :

=SI(B1-A1<6;B1-A1;B1-(A1+0,5))

Si les horaires sont au format heure utiliser :

=SI(B1-A1<1/4;B1-A1; B1-(A1+1/48))

Le souci, c'est qu'il peut y avoir des horaires à cheval sur 2 jours, et il faut pouvoir prendre ça en compte.

La formule ne fonctionnera pas.

bonjour messieurs,

tout d'abord, merci pour la rapidité de vos réponses.

ensuite, pour info, le format est en nombre.

j'ai déjà une première formule pour calculer le nombre d'heures effectuées que ce soit de journée ou de nuit :

=SI(B1<A1;B1+24-A1;B1-A1)

maintenant, je cherche juste une suite à cette formule pour déduire le temps de pause de 0,5 (30 min) si le résultat trouvé en C1 est supérieur à 6

je sais que je peux calculer cette déduction par rapport au résultat obtenu en C1 sur une autre cellule comme ceci :

=SI(C1>=6;C1-0,5;SI(C1<6;C1-0;C1))

mais je préférai tout calculer sur une et même cellule.

merci d'avance

ou plus simple

=SI(C1>=6;C1-0,5;SI(C1<6;C1))

bonjour maqueval,

Si les horaires sont au format nombre utilisez :

=SOMME(SI(B1<=A1;B1+24;B1)-A1;SI(SOMME(SI(B1<=A1;B1+24;B1)-A1)>6;-0,5;0))

super!!! merci à vous njhub, ça fonctionne nickel

j'ai juste ajouter un (=) avant le 6 pour faire la déduction car c'est à partir de 6h de travail que la déduction doit se faire.

par contre si je peux me permettre une question, est-ce normal d'avoir un résultat de 23,5 en C1 si je ne saisi rien en A1 et B1?

en tout cas tu viens de mettre un terme à mes nombreuses recherches sans succès et je t'en remercie beaucoup.

bon confinement à vous

Bonjour à tous,

njhub, ta formule retourne 23.5 si cellules vides. Peut-être que ça n'arrive jamais mais...

Sinon un peu plus court :

=MOD(B2-A2+24;24)-(MOD(B2-A2+24;24)>6)/2

eric

Edit : ah ben si, ça gêne si cellules vides

Vous pouvez corriger avec :

=SI(OU(A1="";B1="");"";SOMME(SI(B1<=A1;B1+24;B1)-A1;SI(SOMME(SI(B1<=A1;B1+24;B1)-A1)>6;-0,5;0)))

=MOD(B2-A2+24;24)-(MOD(B2-A2+24;24)>=6)/2

@ eriiic

magnifique!!!!

merci njhub pour toute l'attention portée à mes demandes

de rien maqueval...