3 feuilles avec macro identique et chacune son bouton + bouton général sur

Bonjour tout est dans le titre,

j'ai 4 feuilles

3 avec la même macro répétée et un bouton identique pour chaque feuille.

1 avec un bouton général qui doit "déclencher les trois autres.

j'ai vraiment essayer plusieurs choses, comme affection d'un bouton. je commence à me familiariser avec le mode création et les différents menus, mais sans résultats.

Bonsoir Pierre, bonsoir le forum,

J'aurais codé comme ça :

Option Explicit
Private V As Variant
Private NB As Integer
Private I As Integer
Private O As Worksheet

Sub NbreCellules()
Set O = ActiveSheet
NB = 0
V = Application.InputBox("Nombres entre lesquels compter les vides :", "Nombre unique", 0, Type:=1)
If V = False Then Exit Sub
O.Range("B2:B" & O.Range("A" & Rows.Count).End(xlUp).Row).ClearContents
For I = 3 To O.Range("A" & Rows.Count).End(xlUp).Row
    If O.Range("A" & I) = "" Then
        NB = NB + 1
    ElseIf O.Range("A" & I) = Val(V) Then
        O.Range("B" & I) = NB
        NB = 0
    End If
Next I
End Sub

Affecte la procédure ci-dessous au bouton 1 :

Sub trois()
Dim J As Byte

V = InputBox("Nombres entre lesquels compter les vides :", "Nombre unique", 0)
If V = False Then Exit Sub
For J = 2 To 4
    NB = 0
    Set O = Worksheets(J)
    O.Range("B2:B" & O.Range("A" & Rows.Count).End(xlUp).Row).ClearContents
    For I = 3 To O.Range("A" & Rows.Count).End(xlUp).Row
        If O.Range("A" & I) = "" Then
            NB = NB + 1
        ElseIf O.Range("A" & I) = Val(V) Then
            O.Range("B" & I) = NB
            NB = 0
        End If
    Next I
Next J
End Sub

Super pour ta réponse rapide !

Je regarde ça.

Je "l'épluche" sur excell 2003 (copie/colle).

et l'ouvrirai sur 2007 cet aprem

je crois que j'ai induit en erreur sur la dde précédente.

car je n'ai pas besoin de conserver un bouton sur chaque feuille.

J'ai donc placé dans module1 la macro et affecté le code du bouton, (active x)

la macro est bien appelée mais ne s'active pas dans les 3 feuilles.

Re,

J'ai compris le problème. En voulant permettre l'utilisation du bouton Annuler dans l'InputBox, j'avais codé :

If V = False Then Exit Sub

Mais si V = 0, ça considère aussi que c'est False. Donc, simplification du code et plus de possibilité d'annuler l'InputBox...

Le code :

Private Sub trois_Click()
Dim J As Byte

V = InputBox("Nombres entre lesquels compter les vides :", "Nombre unique", 0)
For J = 2 To 4
    NB = 0
    Set O = Worksheets(J)
    O.Range("B2:B" & O.Range("A" & Rows.Count).End(xlUp).Row).ClearContents
    For I = 3 To O.Range("A" & Rows.Count).End(xlUp).Row
        If O.Range("A" & I) = "" Then
            NB = NB + 1
        ElseIf O.Range("A" & I) = Val(V) Then
            O.Range("B" & I) = NB
            NB = 0
        End If
    Next I
Next J
End Sub

Bon et bé C nickelChrome !

(et c'est épuisant de ne faire que remercier !)

Re,

C'est une bonne fatigue . Certains ne se fatiguent jamais... Des Corses j'imagine !

Aïe, je me suis mis toute l'île de Beauté à dos... Mais Doumé, c'était pour plaisanter ! Range ton calibre, je t'en prie... Fhummm...

Toulouse (pas en anglais)

Merci encore je cloture