Lier un texbox à une listbox dans un UserForm

Bonjour

Je recherche la formule à mettre dans mon userForm dans un texbox que je souhaite "lier" à une listbox.

Je m'explique : dans ma lisbox je choisit une ville dans la liste déroulante et je souhaite que s'affiche dans le texbox le "secteur" correspondant. (exemple: choix "TOURS" dans ma listbox me donne automatiquement "secteur 1" dans le texbox situé à coté.)

Dans mon classeur j'ai une feuille nommée "liste" avec l'ensemble des villes de mon département en colonne A et les secteurs correspondants pour chaque ville en colonne B.

D'avance merci

Bonjour,

Une piste avec la démarche suivante

1) Dans un nouveau classeur nommez une feuille "liste" et, à partir de A1, tapez des villes en colonne A et des secteurs en colonne B.

2) Créez un UserForm1 avec une ListBox1 et une TextBox1.

3) Dans la fenêtre de code du UserForm1, copiez le code suivant :

'### A adapter ###
Const MA_FEUILLE As String = "liste"
'#################

Private Sub UserForm_Initialize()
Dim S As Worksheet
Dim R As Range
Dim var
Set S = Sheets(MA_FEUILLE)
Set R = S.Range("a1:b" & S.[a65536].End(xlUp).Row & "")
var = R
With ListBox1
  .BoundColumn = 1
  .ColumnCount = 2
  .ColumnWidths = "30;0"
  .List() = var
End With
End Sub

Private Sub ListBox1_Click()
Dim i&
With ListBox1
  For i& = 0 To .ListCount - 1
    If .Selected(i&) = True Then
      TextBox1 = .List(i&, 1)
      Exit For
    End If
  Next i&
End With
End Sub

Lancez le UserForm1.

Cordialement.

PMO

Patrick Morange

Merci beaucoup je vais essayer cela ce soir!!