Aide CODE

Bonjour, j'ai quelque 365 fichier .csv a transférer dans un tableau Excel et j'aimerais savoir si quelqu'un n'aurait pas un moyen pour tout automatiser grâce a une macro ou un code. Merci de me répondre au plus vite.

Bonjour,

Une macro générique (à adapter) :

Sub ImportEnSérie()

Dim Lig As Long, WBdest As Workbook, WBsource As Workbook, NomFichier As String

Application.ScreenUpdating = False
Application.Calculation = xlCalculationManual

Set WBdest = ThisWorkbook 'Affecte ce classeur à la variable WBdest
NomFichier = Dir(WBdest.Path & "\*.csv") 'Défini le nom du répertoire et éventuellement le type de fichier à importer (sinon remplacer csv par *)
'Note : le répertoire par défaut est celui dans lequel est placé ce classeur

Do While NomFichier <> "" 'Boucle sur les fichiers
    Lig = WBdest.Sheets(1).Range("A" & Rows.Count).End(xlUp).Row + 1 'Détermination de la première ligne vierge de la BDD
    Set WBsource = Workbooks.Open(WBdest.Path & "\" & NomFichier) 'Ouverture du fichier à importer
    WBsource.Sheets(1).Range("A1").CurrentRegion.Copy WBdest.Sheets(1).Range("A" & Lig) 'Copier/coller des données
    WBsource.Close False 'Fermeture du fichier csv (sans enregistrer)
    WBdest.Sheets(1).Rows(Lig).Delete 'Suppression de la ligne d'en-tête du csv (précéder cette instruction d'une apostrophe si inutile)
    NomFichier = Dir() 'Passage au fichier suivant
Loop

Application.Calculation = xlCalculationAutomatic

End Sub

MERCI sa marche au poile, je la copie colle dan d’un document Word gardée bien précieusement

Louni06 a écrit :

MERCI sa marche au poile, je la copie colle dan d’un document Word gardée bien précieusement

Merci du retour, pense à valider le sujet !