Retrouver la date avec seulement l'année, le N° de semaine et le jour

Bonjour à tous,

Merci d'avance pour votre aide

Je cherche à retrouver la date et l'afficher en format long à partir des infos suivantes :

(colonne A) Année, (colonne B) N° de semaine et (colonne C) Jour et le résultat en colonne D

J'ai voulu m'appuyer sur des cas du forum mais sans résultats

Exemple avec le sujet d' "212bashaut" et la formule :

=DATE(A2;1;3)-JOURSEM(DATE(A2;1;3)+2

Avec en A1 numéro de semaine et A2 l'année

Je suis sous excel 365

Bonjour et bienvenue

As-tu un fichier ?

Je me pose la question du contenu exact dans la colonne C et le format appliqué

Bonjour,

Un exemple en considérant que le jour soit le numéro du jour ISO dans la semaine.

Cdlt.

6kiwies.xlsx (11.31 Ko)
=[@Semaine]*7+[@NumJour]-(JOURSEM(DATE([@Année];1;4);2)+3)+DATE([@Année];1;0)

Je te propose ceci:

=DATE(A1;1;4)+7*(B1-1)+C1-JOURSEM(DATE(A1;1;2))

Avec A1 l'année, B1 la semaine, C1 le jour

Woha rapide !

ci-joint le fichier d'export.

la colonne C ne contient que les jours de la semaines, format standard.

Je me pose la question de savoir si je peux me passer de cette formule?

Le but est de faire des stats (TCD) avec une "chronologie" (dans analyse du TCD - Insérer une chronologie)

Merci beaucoup

9export.csv (373.00 Octets)

Bonjour,

Un exemple en considérant que le jour soit le numéro du jour ISO dans la semaine.

Cdlt.

kiwies.xlsx

=[@Semaine]*7+[@NumJour]-(JOURSEM(DATE([@Année];1;4);2)+3)+DATE([@Année];1;0)

Peut-on récupérer le "NumJour" à partir du "JourSemaine" (vu dans un autre sujet mais sur excel 2003 =>j'ai tenté de récupérer l'index du JourSemaine mais cela n'a pas fonctionné sur excel 365)

J'ai mis un exemple dans un post plus bas haut (export.cvs).

Merci de votre aide

Re,

Une nouvelle proposition réalisée avec Récupérer et transformer des données (Power Query).

A te relire.

Cdlt.

6kiwies2.xlsx (19.79 Ko)

Re,

Une nouvelle proposition réalisée avec Récupérer et transformer des données (Power Query).

A te relire.

Cdlt.

kiwies2.xlsx

Merci cela m'a aidé :

J'utilise la formule du dessous pour récupérer le numéro de jour :

=SI([@Jour]="Lundi";1;SI([@Jour]="Mardi";2;SI([@Jour]="Mercredi";3;SI([@Jour]="Jeudi";4;SI([@Jour]="Vendredi";5;SI([@Jour]="Samedi";6;SI([@Jour]="Dimanche";7;"")))))))

Puis je récupérer la date :

=[@[N° semaine]]*7+[@N°Jour]-(JOURSEM(DATE([@[N° année]];1;4);2)+3)+DATE([@[N° année]];1;0)

=SI([@Jour]="Lundi";1;SI([@Jour]="Mardi";2;SI([@Jour]="Mercredi";3;SI([@Jour]="Jeudi";4;SI([@Jour]="Vendredi";5;SI([@Jour]="Samedi";6;SI([@Jour]="Dimanche";7;"")))))))

Fais alors un tableau de correspondance !

Re,

Avec Excel 365, tu peux envisager d'utiliser ces 2 fonctions :

=SI.CONDITIONS([@Jour]="lundi";1;[@Jour]="mardi";2;[@Jour]="mercredi";3;[@Jour]="jeudi";4;[@Jour]="vendredi";5;[@Jour]="samedi";6;[@Jour]="dimanche";7)

=SI.MULTIPLE([@Jour];"lundi";1;"mardi";2;"mercredi";3;"jeudi";4;"vendredi";5;"samedi";6;"dimanche";7)

Cdlt.

Bonjour,

Quand on traite de dates, nous avons qques connaissances.

J'ajoute donc un grain de sel en passant, pas testé avec 365, mais ça devrait le faire.

Sur le besoin de "JOURSEM() inversé", considérez ces approches qui facilitent écriture et lecture.

A - On cherche l'occurrence dans un string de fragments signifiants (attention au premier caractère bidon, ici le _, mais on peut mettre n'imp.) :

=SIERREUR(TROUVE(GAUCHE([@Jour];2);"_LuMaMeJeVeSaDi")/2;0)

Si dates anglaises, le string est "$MoTuWeThFrSaSu".

B - Plus élégant pour les puristes, on recherche dans une "matrice manuelle" (attention aux accolades {} pour définir la matrice)

=SIERREUR(EQUIV(GAUCHE([@Jour];2);{"Lu";"Ma";"Me";"Je";"Ve";"Sa";"Di"};0);0)

mais c'est plus fastidieux à saisir.

C - Et pour se chauffer les neurones, une gentille formule matricielle itérative :

{=SOMME(SI(TEXTE(DATE(2001;1;LIGNE($A$1:$A$7));"jjjj")=[@Jour];LIGNE($A$1:$A$7);0))}

XL2016 le calcule même sans le Ctrl+Shift+Enter.

Sur 365, j'ai des doutes que ça passe.

Fichier joint complet pour illustrer.

Vous qui voyez....

Merci de ce problème plutôt récréatif.

Cdlmt.

Merci pour les différentes méthodes que je vais tester de ce pas !

Rechercher des sujets similaires à "retrouver date seulement annee semaine jour"