Macro pour télécharger plusieurs onglets en PDF

Bonjour à tous,

Je suis super embêtée, je n'arrive pas à créer une macro pour sauvegarder ma demande d'achat (PO) en PDF.

J'ai crée le bouton pour y associer la macro en onglet 2 "demande d'achat"

Voila ce que je souhaiterais faire lorsque l'on clique sur ce bouton :

- Sauvegarder en PDF les onglets suivants : "demande d'achat" + "choix devis" + "devis"

Laisser le choix du nom et de l'emplacement

Pourriez-vous m'aider svp ??

Un grand merci à mes sauveurs

Bonjour Sandra,

voici le code si on veut un PDF unique pour les trois onglets:

Sub test()

    Dim Fichier As Variant
    Fichier = Application.GetSaveAsFilename(FileFilter:="Adobe PDF File (*.pdf), *.pdf")
    If Fichier <> False Then

        Application.ScreenUpdating = False

        ThisWorkbook.Sheets(Array("demande d'achat", "choix devis", "devis")).Select
        ActiveSheet.ExportAsFixedFormat Type:=xlTypePDF, Filename:= _
                                        Fichier, Quality:=xlQualityStandard, IncludeDocProperties:=True, _
                                        IgnorePrintAreas:=False, OpenAfterPublish:=False
    End If

    Application.ScreenUpdating = True

End Sub

Cordialement

Pour un fichier PDF pour chaque onglet:

Sub test2()

    Dim Fichier As Variant
    Dim i As Integer

    Application.ScreenUpdating = False

    For i = 2 To 4 '<<================ du deuxième au quatrième onglet
        Fichier = Application.GetSaveAsFilename(FileFilter:="Adobe PDF File (*.pdf), *.pdf")

        If Fichier <> False Then
            ThisWorkbook.Sheets(i).ExportAsFixedFormat Type:=xlTypePDF, Filename:= _
                                                       Fichier, Quality:=xlQualityStandard, IncludeDocProperties:=True, _
                                                       IgnorePrintAreas:=False, OpenAfterPublish:=False

        End If

    Next i

    Application.ScreenUpdating = True

End Sub