Trouver une valeur en fonction de 2 variables
Bonjour,
Je n'arrive pas à trouver la formule qui va bien pour mon problème
Bon c'est un peu compliqué mais j'ai essayé d'expliquer le mieux possible
Mon fichier excel me permet lorsque que je tape un indice de charge de trouver une charge (en kg) et lorsque que je tape un indice de vitesse de trouver une vitesse (en km/h).
Pour cela la feuille "Tab Indice de ChargeVitesse" est utilisée.
Or j'aimerais que lorsque je tape dans dans la cellule "vitesse souhaitée" la vitesse que je désire, j'obtienne dans la case "Charge Obtenue" la "charge par roue" additionnée par le pourcentage correspondant à l'indice de vitesse de départ mais multiplié par le pourcentage correspondant à la vitesse désirée (dans la feuille "Tab de Variation de Charge)
Voici un exemple pour mieux comprendre
Informations :
Indice de charge : 151
Indice de vitesse : D
Charge par roue : 4140
Charge par essieu : 8280
Vitesse : 65
Je souhaiterais réduire ma vitesse à 40 km/h donc je rentre 40 dans la cellule "vitesse souhaité"
Et une fois que j'ai tapé 40, le calcul va chercher la correspondance dans "Tab Variation de Charge" afin d'appliquer le pourcentage correspondant aux indice de vitesse D, dans ce cas 36%.
Ce qui fait un résultat dans la cellule "Charge obtenue" de 4140 + 36% = 5630,4
Voilà je vous remercie de l'aide que vous pourriez m'apporter !!
Salut,
Copie-colle ça en L24 :
=D20*(1+INDEX('Tab Variation de Charge'!A1:E15;EQUIV(L20;'Tab Variation de Charge'!A1:A15;0);EQUIV(D10;'Tab Variation de Charge'!A1:E1;0)))Normalement ça fonctionne,
Girodo,
Bonjour,
=SI(P7=2;RECHERCHEV(D7;'Tab Indice de ChargeVitesse'!A:B;2;FAUX);RECHERCHEV(D7;'Tab Indice de ChargeVitesse'!A:B;2;FAUX)*1,2)*(1+SIERREUR(DECALER('Tab Variation de Charge'!$A$1;EQUIV(L20;'Tab Variation de Charge'!$A$2:$A$14;0);EQUIV(D10;'Tab Variation de Charge'!$B$1:$E$1;0));0))edit : bonjour Girodo, je n'avais pas vu ta réponse ... et ta formule est un poil plus simple sans le DECALER
Salut Steelson
edit : bonjour Girodo, je n'avais pas vu ta réponse ... et ta formule est un poil plus simple sans le DECALER
Pour une fois que c'est moi le plus rapide :p
Girodo,
Merci à vous Girodo et Steelson, vos formule marche a merveille, et j'avous que j'ai choisis la tienne Steelson par sa simplicité
Celle de Girodo est mieux !
mixée avec mon début de formule :
=SI(P7=2;RECHERCHEV(D7;'Tab Indice de ChargeVitesse'!A:B;2;FAUX);RECHERCHEV(D7;'Tab Indice de ChargeVitesse'!A:B;2;FAUX)*1,2)*(1+
SIERREUR(INDEX('Tab Variation de Charge'!A1:E15;EQUIV(L20;'Tab Variation de Charge'!A1:A15;0);EQUIV(D10;'Tab Variation de Charge'!A1:E1;0));0)
)