TCD - rétablir le nom source d'une cellule

Bonjour,

Dans un TCD il est possible d'éditer librement une cellule, par exemple :

Si le champ est PAYS, avec les informations suivantes :

• France
• Allemagne
• Espagne

Il est possible d’éditer, par exemple France, et de l'écrire "Fr"

• Fr
• Allemagne
• Espagne

Comment peut-on réinitialiser la cellule, pour qu'elle redevienne ce qu'elle était à l'origine de la source des données, c'est à dire "France" ?

En vous remerciant par avance de vos solutions.

Bonjour PetitChat3333,

Je te propose le code suivant à adapter à ton cas:

Option Explicit
Const cTCDName = "TCD1"       'A adapter pour indiquer le nom correct de ton TCD
Const cChampPays = "Pays"     'A adapter pour indiquer le nom correct de ta source de données indiquant le pays
Const cSheetName = "Feuil1"   'A adapter pour indiquer le nom correct de ta feuille EXCEL
Sub ReinitLabelsPays()
    Dim oPivotItem As PivotItem
    Dim oTCD As PivotTable
    Dim oSheet As Worksheet
    Dim oPivotField As PivotField

    'On réfère la feuille EXCEL
    Set oSheet = ThisWorkbook.Worksheets(cSheetName)
    'On réfère le TCD
    Set oTCD = oSheet.PivotTables("TCD1")
    'On réfère le champ source de la colonne dont les libellés sont à rétablir
    Set oPivotField = oTCD.PivotFields(cChampPays)

    'On boucle sur les libellés de la colonne
    For Each oPivotItem In oPivotField.PivotItems
        'On rétablit le libellé initial
        oPivotItem.Caption = oPivotItem.SourceName
    Next

End Sub

Bonjour GVIALLES,

Merci beaucoup pour ta réponse, cela fonctionne très bien.

En te souhaitant une bonne journée.